type
  TAuthHandler = class
  public
    FUserName: String;
    FPassword: String;
    procedure NetHTTPClientAuthEvent(const Sender: TObject;
      AnAuthTarget: TAuthTargetType; const ARealm, AURL: string;
      var AUserName, APassword: string; var AbortAuth: Boolean;
      var Persistence: TAuthPersistenceType);
  end;

procedure TAuthHandler.NetHTTPClientAuthEvent(const Sender: TObject;
  AnAuthTarget: TAuthTargetType; const ARealm, AURL: string; var AUserName,
  APassword: string; var AbortAuth: Boolean;
  var Persistence: TAuthPersistenceType);
begin
  if AnAuthTarget = TAuthTargetType.Server then
  begin
    AUserName := FUserName;
    APassword := FPassword;
  end;
end;

function XSendRequest(Method, URL, CustomHeaders, Body, Login, Password: string): string;
var
  SourceStream: TStringStream;
  CustomHeadersList: TStrings;
  I: Integer;
  HTTPClient: THTTPClient;
  Request: IHTTPRequest;
  iResponse: IHTTPResponse;
  AuthHandler: TAuthHandler;

begin
  Result := '';
  SourceStream := TStringStream.Create(UTF8Encode(Body));
  HTTPClient := THTTPClient.Create;
  AuthHandler := TAuthHandler.Create;                           // basic auth
  try
    AuthHandler.FUserName := Login;                             // basic auth
    AuthHandler.FPassword := Password;                          // basic auth
    HTTPClient.AuthEvent := AuthHandler.NetHTTPClientAuthEvent; // basic auth
    try
      Request := HTTPClient.GetRequest(Method, URL);
(*
      // this raises (ENetHTTPRequestException) Error adding header: (87) The parameter is incorrect
      if Login + Password <> '' then
        Request.AddHeader('Authorization', 'Basic ' + TNetEncoding.Base64.Encode(Login + ':' + Password));
*)
      CustomHeadersList := TStringList.Create;
      try
        CustomHeadersList.Text := CustomHeaders;
        Request.SourceStream := SourceStream;
        for I := 0 to Pred(CustomHeadersList.Count) do
          Request.AddHeader(CustomHeadersList.Names[I],  CustomHeadersList.ValueFromIndex[I]);
      finally
        CustomHeadersList.Free;
      end;

      iResponse := HTTPClient.Execute(Request);
      Result := iResponse.ContentAsString;

    except
      on E: Exception do
      begin
        SendDebugError('SendRequest exception: '+E.Message);
      end
    end;
  finally
    AuthHandler.Free;
    SourceStream.Free;
    HTTPClient.Free;
  end;
end;