procedure FDSetValueToAllRecords(ADataSet: TFDDataSet; const AFieldName: String; const AValue: Variant);
var
  rState: TFDDatSLoadState;
  i, j: Integer;
  oRow: TFDDatSRow;
  oColumn: TFDDatSColumn;
  Fields: TList<TField>;
  bArray: Boolean;
  vValueToSet: Variant;
begin
  bArray := VarIsArray(AValue);

  Fields := TList<TField>.Create;
  try
    ADataSet.GetFieldList(Fields, AFieldName);
    ADataSet.Table.BeginLoadData(rState, lmHavyLoading);
    try
      for i := 0 to Fields.Count - 1 do
      begin
        oColumn := ADataSet.Table.Columns.ColumnByName(Fields[i].FieldName);
        for j := 0 to ADataSet.Table.Rows.Count - 1 do
        begin
          oRow := ADataSet.Table.Rows[j];
          if not (oRow.RowState in [rsInserted, rsModified, rsUnchanged]) then
            Continue;

          if bArray then
            vValueToSet := AValue[i]
          else
            vValueToSet := AValue;

          if not VarSameValue(oRow.ValueO[oColumn], vValueToSet) then
          begin
            oRow.BeginEdit;
            try
              oRow.SetData(oColumn, vValueToSet);
            finally
              oRow.EndEdit;
            end;
          end;
        end;
      end;
    finally
      ADataSet.Table.EndLoadData(rState);
    end;
  finally
    Fields.Free;
  end;
end;