uses
  Controls, Graphics;

type
  TDraggedText = class(TDragControlObject)
  private
    FDragImages: TDragImageList;
    FText: string;
  protected
    function GetDragImages: TDragImageList; override;
  public
    constructor Create(AControl: TControl; AText: string); reintroduce;  
    destructor Destroy; override;
    procedure HideDragImage; override;
    procedure ShowDragImage; override;
    property DragText: string read FText write FText;
  end;

implementation

{ TDraggedText }

constructor TDraggedText.Create(AControl: TControl; AText: string);
begin
  inherited Create(AControl);
  FText := AText;
end;

destructor TDraggedText.Destroy;
begin
  FDragImages.Free;
  inherited;
end;

procedure TDraggedText.HideDragImage;
begin
  GetDragImages.HideDragImage;
end;

procedure TDraggedText.ShowDragImage;
begin
  GetDragImages.ShowDragImage;
end;

type
  TMyControl = class(TControl);

function TDraggedText.GetDragImages: TDragImageList;
var
  Bmp: TBitmap;
begin
  if FDragImages = nil then
    begin
      FDragImages := TDragImageList.Create(nil);
      Bmp := TBitmap.Create;
      try
        Bmp.Canvas.Font.Assign(TMyControl(Control).Font);
        Bmp.Canvas.Font.Color := clHotlight;
        Bmp.Width := Bmp.Canvas.TextWidth(FText);
        Bmp.Height := Bmp.Canvas.TextHeight(FText);
        Bmp.Canvas.TextOut(0, 0, FText);
        FDragImages.Width := Bmp.Width;
        FDragImages.Height := Bmp.Height;
        FDragImages.SetDragImage(FDragImages.Add(Bmp, nil), 0, 0);
      finally
        Bmp.Free;
      end;
    end;
  Result := FDragImages;
end;

end.