unit mkMoneyEdit;

interface

uses
  Winapi.Messages, System.SysUtils, System.Classes, Vcl.Controls, Vcl.StdCtrls;

type
  TMKMoneyEdit = class(TEdit)
  private
    function GetAsValue: Integer; inline;
    procedure SetByValue(const Value: Integer); inline;
  protected
    procedure CMEnter(var Message: TCMEnter); message CM_ENTER;
    procedure CMExit(var Message: TCMExit); message CM_EXIT;
    procedure KeyPress(var Key: Char); override;
    procedure WMPaste(var Message: TWMPaste); message WM_PASTE;
  public
    property Value: Integer read GetAsValue write SetByValue;
  end;

function FormatAsDecimal(const SourceText: string): string;
function RemoveNonDigits(const SourceText: string; AsPenny: Boolean): string;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Samples', [TMKMoneyEdit]);
end;

function FormatAsDecimal(const SourceText: string): string;
const
  PennyChars: Integer = 3;
var
  CharIndex: Integer;     // индекс текущего символа
  TextLength: Integer;    // длина строки
  PennyValue: string;
begin
  { Проверка на пустую строку }
  if SourceText.IsEmpty then
    Exit(SourceText);

  CharIndex := SourceText.IndexOf(FormatSettings.DecimalSeparator);
  if CharIndex < 0 then
  begin
    PennyValue := FormatSettings.DecimalSeparator + '00';
    TextLength := SourceText.Length
  end else begin
    PennyValue := SourceText.Substring(CharIndex, PennyChars) + '00';
    SetLength(PennyValue, 3);
    TextLength := CharIndex;
  end;

  { Тривиальный вариант: 3 или менее цифр }
  if TextLength <= 3 then
    Exit(SourceText.Substring(0, TextLength) + PennyValue);

  { Пример: '12345678' = 8 + (7 div 3) пробелов + копейки = 13 символов ('12 345 678.00') }
  SetLength(Result, TextLength + (TextLength - 1) div 3 + PennyChars);

  { Копируем копейки }
  CharIndex := Result.Length - PennyChars + 1;
  Move(PennyValue[1], Result[CharIndex], PennyChars * SizeOf(Char));

  { Копируем число по группам из 3х разрядов }
  while TextLength > 3 do
  begin
    Dec(TextLength, 3);
    Move(SourceText[TextLength + 1], Result[CharIndex - 3], 6);
    Dec(CharIndex, 4);
    Result[CharIndex] := #32;
  end;
  Move(SourceText[1], Result[1], TextLength * SizeOf(Char));

end;

function RemoveNonDigits(const SourceText: string; AsPenny: Boolean): string;
var
  CharIndex: Integer;  // индекс символа в новой строке
  LastIndex: Integer;  // индекс десятичного разделителя
  SourceChar: Char;    // текущий символ
begin
  CharIndex := 1;
  LastIndex := 0;
  SetLength(Result, SourceText.Length);
  for SourceChar in SourceText do
  begin
    case SourceChar of
      '0'..'9': Result[CharIndex] := SourceChar;
      ',', '.':
        if AsPenny then
        begin
          LastIndex := CharIndex;
          Continue;
        end else begin
          LastIndex := CharIndex + 1;
          Result[CharIndex] := FormatSettings.DecimalSeparator;
        end
    else
      Continue;
    end;
    Inc(CharIndex);
    if (LastIndex > 0) and (CharIndex - LastIndex >= 2) then
      Break;
  end;
  SetLength(Result, CharIndex - 1);
end;

{ TMKMoneyEdit }

procedure TMKMoneyEdit.CMEnter(var Message: TCMEnter);
begin
  inherited;
  Text := RemoveNonDigits(Text, False);
end;

procedure TMKMoneyEdit.CMExit(var Message: TCMExit);
begin
  inherited;
  Text := FormatAsDecimal(Text);
end;

function TMKMoneyEdit.GetAsValue: Integer;
begin
  Result := StrToIntDef(RemoveNonDigits(Text, True), 0);
end;

procedure TMKMoneyEdit.KeyPress(var Key: Char);
begin
  case Key of
    '0'..'9', #8: inherited KeyPress(Key);
    ',', '.':
      if Pos(FormatSettings.DecimalSeparator, Text) = 0 then
      begin
        Key := FormatSettings.DecimalSeparator;
        inherited KeyPress(Key);
      end else
        Key := #0;
  else
    Key := #0;
  end;
end;

procedure TMKMoneyEdit.SetByValue(const Value: Integer);
begin
  Text := FormatAsDecimal((Value / 100).ToString);
end;

procedure TMKMoneyEdit.WMPaste(var Message: TWMPaste);
var
  ValidText: string;
begin
  inherited;
  ValidText := RemoveNonDigits(Text, False);
  if not Focused then
    ValidText := FormatAsDecimal(ValidText);
  Text := ValidText;
end;

end.