program Project1;

{$APPTYPE CONSOLE}
{$U-}{$V+}{$B-}{$X+}{$T+}{$P+}{$H+}{$J-}{$Z1}{$A4}
{$O+}{$R-}{$I-}{$Q-}{$W-}

{$R *.res}

uses
  SysUtils, Math, TypInfo, Diagnostics, Generics.Defaults;

type

  TTest<T> = class
  private
    class var
      FCmp: IComparer<T>;
      FIsSigned: Boolean;
      FIsDouble: Boolean;

    class constructor ClassCreate;
  public
    function IsMore1(const T1, T2: T): Boolean; inline;
    function IsMore2(const T1, T2: T): Boolean; inline;
  end;

class constructor TTest<T>.ClassCreate;
var
  LTypeData: PTypeData;
begin
  FCmp := TComparer<T>.Default;

  LTypeData := PTypeInfo(TypeInfo(T)).TypeData;
  case GetTypeKind(T) of
    tkInteger:
    begin
      FIsSigned := (LTypeData.OrdType in [otSByte, otSWord, otSLong]);
    end;
    tkInt64:
    begin
      FIsSigned := (LTypeData.MinInt64Value < LTypeData.MaxInt64Value);
    end;
    tkFloat:
    begin
      FIsDouble := (LTypeData.FloatType = ftDouble);
    end;
  end;
end;

function TTest<T>.IsMore1(const T1, T2: T): Boolean;
begin
  Result := (FCmp.Compare(T1, T2) >= 0);
end;

function TTest<T>.IsMore2(const T1, T2: T): Boolean;
begin
   case GetTypeKind(T) of
     tkInteger:
     begin
       case SizeOf(T) of
         SizeOf(Byte):
         begin
           if (FIsSigned) then
             Result := PShortInt(@T1)^ >= PShortInt(@T2)^
           else
             Result := PByte(@T1)^ >= PByte(@T2)^;
         end;
         SizeOf(Word):
         begin
           if (FIsSigned) then
             Result := PSmallInt(@T1)^ >= PSmallInt(@T2)^
           else
             Result := PWord(@T1)^ >= PWord(@T2)^;
         end;
       else
         if (FIsSigned) then
           Result := PInteger(@T1)^ >= PInteger(@T2)^
         else
           Result := PCardinal(@T1)^ >= PCardinal(@T2)^;
       end;
     end;
     tkInt64:
     begin
       if (FIsSigned) then
         Result := PInt64(@T1)^ >= PInt64(@T2)^
       else
         Result := PUInt64(@T1)^ >= PUInt64(@T2)^;
     end;
     tkFloat:
     begin
       case SizeOf(T) of
         SizeOf(Single):
         begin
           Result := PSingle(@T1)^ >= PSingle(@T2)^;
         end;
         {$if SizeOf(Extended) > SizeOf(Double)}
         SizeOf(Extended):
         begin
           Result := PExtended(@T1)^ >= PExtended(@T2)^;
         end;
         {$ifend}
       else
         if (FIsDouble) then
           Result := PDouble(@T1)^ >= PDouble(@T2)^
         else
           Result := PInt64(@T1)^ >= PInt64(@T2)^;
       end;
     end;
   else
     raise Exception.Create('Error Message');
   end;
end;

begin
  var Test := TTest<Integer>.Create;
  var T := TStopwatch.StartNew;
  for var i := 0 to 100000000 do
  begin
    Test.IsMore1(1, 2);
  end;
  var R1 := T.ElapsedMilliseconds;

  T := TStopwatch.StartNew;
  for var i := 0 to 100000000 do
  begin
    Test.IsMore2(1, 2);
  end;
  var R2 := T.ElapsedMilliseconds;

  Writeln('Default: ', R1, 'ms');
  Writeln('Inline: ', R2, 'ms');
  Writeln('Profit: x', (R1 / R2):0:2);

  Writeln;
  Write('Press Enter to quit');
  ReadLn;
end.