procedure TDMTillSlipShtr.DataModuleCreate(Sender: TObject);
begin
  try
    ECR := CreateOleObject('AddIn.DrvFR');
  except
    ShowMessage('Не удалось создать объект общего драйвера ККМ Штрих !');
  end;
end;

procedure TDMTillSlipShtr.DataModuleDestroy(Sender: TObject);
begin
    ECR := 0;  // разрушаем объект драйвера
end;

procedure TDMTillSlipShtr.ChangeAdminKKM(AUser: string);
begin
 try
   ECR.Password:=30;    //Совет Близнец1980
   ECR.TableNumber:=2;  //https://www.sql.ru/forum/actualutils.aspx?action=gotomsg&tid=1276532&msg=20939695]Delphi + онлайн-кассы
   ECR.RowNumber:=30;
   ECR.FieldNumber:=2;
   ECR.ValueOfFieldString:=AUser; // КАССИР .....  'ÊÀÑÑÈÐ '+ 
   ECR.WriteTable;
except
  on E: Exception do begin
                       showmessage('Ошибка установки кассира:'+E.Message);
                     end;
 end;
end;

procedure TDMTillSlipShtr.Check(AResultCode: Integer);
begin
  if AResultCode <> 0
    then begin
         //  raise Exception.Create(ECR.ResultCodeDescription);  // или
           ShowMessage(ECR.ResultCodeDescription);
           Abort;
         end;
end;

function TShtrService.ZeroTillSlip: boolean;  //Нулевой чек
begin
 Result:=False;
 with DMTillSlipShtr do
  try
    Check(ECR.LockPort);  // занимаем порт
    ECR.Password := 30;
    Check(ECR.GetECRStatus);
    if ECR.ECRMode = 8 then Check(ECR.SysAdminCancelCheck); //если есть открытый чек, то аннулируем его
    ECR.CheckType := 0;
    Check(ECR.OpenCheck);

    ECR.Price := 0;
    ECR.Quantity := 1;
    ECR.Department := 1;
    ECR.Tax1 := 0;
    ECR.Tax2 := 0;
    ECR.Tax3 := 0;
    ECR.Tax4 := 0;
    ECR.StringforPrinting := 'Уголь активированный'; //Название товара
    Check(ECR.Sale); // Продажа

    ECR.Summ1:=0;  // Наличными
    Check(ECR.CloseCheck);
    Result:=True;
 finally
  ECR.UnlockPort;
 end;
end;

function TShtrService.X_Report: boolean; // X - отчет
begin
 Result:=False;
 with DMTillSlipShtr do
  try
    Check(ECR.LockPort);  // занимаем порт
    ECR.Password := 30;   // устанавливаем пароль системного администратора ККМ
    Check(ECR.GetECRStatus);
    if ECR.ECRMode = 8 then Check(ECR.SysAdminCancelCheck); //если есть открытый чек, то аннулируем его
    ECR.PrintReportWithoutCleaning;
    Result:=True;
 finally
  ECR.UnlockPort;
 end;
end;

function TShtrService.Z_Report: boolean;   // Z - отчет
begin
 Result:=False;
 case MessageDlg('Закрыть смену и напечатать Z-отчёт?', mtConfirmation, [mbYes, mbCancel], 0) of
  mrYes: with DMTillSlipShtr do
           try
            Check(ECR.LockPort);  // занимаем порт
            ECR.Password := 30;   // устанавливаем пароль системного администратора ККМ
            Check(ECR.GetECRStatus);
            if ECR.ECRMode = 8 then begin
                                     Check(ECR.SysAdminCancelCheck); //если есть открытый чек, то аннулируем его
                                     Check(ECR.GetECRStatus);
                                    end;
            if ((ECR.ECRMode = 2) or (ECR.ECRMode = 3))
              then begin
                    ECR.PrintReportWithCleaning;
                    Result:=True;
                    Q_Z.ExecQuery;  // Обработка в БД по закрытию смены
                   end
              else ShowMessage('Смена не была открыта! Напечатать Z-отчёт нельзя!');
           finally
               ECR.UnlockPort;
           end;
  mrCancel: exit;
  end;
end;

procedure TShtrService.ShowPropertiesShtr;
begin
   DMTillSlipShtr.ECR.ShowProperties;
end;

function TShtrService.GetSerialNumber: PChar;
var s: string;
begin
 s:='';
 with DMTillSlipShtr do
  try
    Check(ECR.LockPort);  // занимаем порт
    ECR.Password := 30;
    Check(ECR.GetECRStatus);
    s:=ECR.SerialNumber;
 finally
    if s='' then s:=' не обнаружен';
    Result:=PChar(s);
    ECR.UnlockPort;
 end;
end;

function TShtrService.PrintTillSlipShtr(DBHandle: TISC_DB_HANDLE; AQuery: TpFIBDataSet; ATag: integer; AListSystemVariables: TStringList): boolean;
begin
 Result:=False;
 with DMTillSlipShtr do
  try
    QFiskCheckRec.Close;
    QFiskCheck.Close;
    DB.Handle:=DBHandle;
    QFiskCheck.ParamByName('X').AsInteger:=ATag;
    QFiskCheck.Open;  //Открываем из БД нужный чек
    if QFiskCheck.RecordCount=0 then raise Exception.Create('Чек в БД отсутствует!');

    Check(ECR.LockPort);  // занимаем порт
    ChangeAdminKKM(QFiskCheckCASHIER.Value); //Подменяем СИСТ.АДМИНИСТРАТОР на пользователя ECR.Password := 30;
    Check(ECR.GetECRStatus);
    if ECR.ECRMode = 8 then Check(ECR.SysAdminCancelCheck); //если есть открытый чек, то аннулируем его
    if QFiskCheckCHECKTYPE.AsInteger=1 then ECR.CheckType := 0;  // Продажа
    if QFiskCheckCHECKTYPE.AsInteger=2 then ECR.CheckType := 2;  // Возврат
    Check(ECR.OpenCheck);

    QFiskCheckRec.Open; // Открываем из БД табличную часть чека
    QFiskCheckRec.First;
    While not QFiskCheckRec.Eof
     do begin
          if QFiskCheckRecTIP.Value=0  // нулевой чек
            then ECR.Price := 0
            else ECR.Price := round(QFiskCheckRecPRICE.Value*100)/100;//Округление до второго знака !!!
          ECR.Quantity := round(QFiskCheckRecCOUNTS.Value*1000)/1000;
          ECR.Department := QFiskCheckRecDEPARTMENT.Value;
          ECR.Tax1 := 0;
          ECR.Tax2 := 0;
          ECR.Tax3 := 0;
          ECR.Tax4 := 0;  //    ECR.TaxTypeNumber :=QFiskCheckRecTAXTYPENUMBER.Value;
          ECR.StringforPrinting := copy(QFiskCheckRecNAME.Value,1,48);//Название товара
          if (QFiskCheckCHECKTYPE.AsInteger=1) then Check(ECR.Sale);       // Продажа
          if (QFiskCheckCHECKTYPE.AsInteger=2) then Check(ECR.ReturnSale); // Возврат
          QFiskCheckRec.Next;
        end;

    if ((QFiskCheckPHONE.Value<>'') or (QFiskCheckMAIL.Value<>'')) then
      begin    // передача почты или сотового номера, приоритет - почта
        if (QFiskCheckMAIL.Value<>'') then ECR.CustomerEmail := QFiskCheckMAIL.Value
                                      else ECR.CustomerEmail := QFiskCheckPHONE.Value;
        ECR.FNSendCustomerEmail;
      end;

    Check(ECR.CheckSubTotal);   //Подсчитали итог чека для наличных в Summ1
    ECR.Summ2:=0;
    ECR.Summ3:=0;
    ECR.Summ4:=0;
    if QFiskCheckTYPECLOSE.AsInteger>0 
      then begin      // если оплата по карте
              ECR.Summ2:=ECR.Summ1;  // на разных аппаратах под банк.карты выделяют разные регистры
              ECR.Summ1:=0;          // Summ2 - Summ4, посмотреть можно в сойствах таблицы 16
           end;
    Check(ECR.CloseCheck);

    QFiskCheck.Edit;   // Фиксируем в БД, что чек ушел в ККМ
    QFiskCheckDEVICEID.Value:=ECR.SerialNumber; //Доступен после успешного ECR.GetECRStatus
    QFiskCheck.Post;
    Result:=True;
 finally
  QFiskCheckRec.Close;
  QFiskCheck.Close;
  ECR.UnlockPort;
 end;
end;