TLGTAnalysisForm = class(TFrmMyChild_)
private
	{ Private declarations }
	FDateBegin, FDateEnd: TDateTime;
	FDynamicFields: TList<TFloatField>;
	FDynamicColumns: TList<TColumnEh>;
	FStartPeriodOffset: Integer;
end;

procedure TLGTAnalysisForm.FormCreate(Sender: TObject);
begin
  inherited;
  FDynamicFields := TList<TFloatField>.Create;
  FDynamicColumns := TList<TColumnEh>.Create;
end;

procedure TLGTAnalysisForm.RefreshQuery;
var
  DatePeriodAnalitFilter: IDatePeriodAnalitFilter;
begin
  //dbgMain.StartLoadingStatus();;
  dbgMain.BeginLayout;
  try
    mtMain.Close;	// <- MemTableEh отображаемый в гриде
    mtMain.DestroyTable;
    dbgMain.DataGrouping.Active := False;
    DeleteDynamicFields;
    DatePeriodAnalitFilter := (FFilters.FindFilter(cstDatePeriodAnalit, 0) as IDatePeriodAnalitFilter);
    FDateBegin := DatePeriodAnalitFilter.Value1; // Начало периода
    FDateEnd := DatePeriodAnalitFilter.Value2; // Конец периода
    CreateDynamicFields;
    TAnalitFiltersFireDACQueryBuilder.MakeFilter(FFilters, fdqMain);
    fdqMain.Open; // <- FDQuery содержащий данные которые надо разложить по колонкам
    mtMain.CreateDataSet;
    dbgMain.DataGrouping.Active := True;
  finally
    //dbgMain.FinishLoadingStatus();
    dbgMain.EndLayout;
  end;
end;

procedure TLGTAnalysisForm.DeleteDynamicFields;
var
  I: Integer;
begin
  for I := FDynamicColumns.Count - 1 downto 0 do
    FDynamicColumns[I].Free;
  FDynamicColumns.Clear;
  for I := FDynamicFields.Count - 1 downto 0 do
    FDynamicFields[I].Free;
  FDynamicFields.Clear;
end;

procedure TLGTAnalysisForm.CreateDynamicColumn(const Field: TField);
var
  ColumnEh: TColumnEh;
begin
  ColumnEh := dbgMain.Columns.Add;
  FDynamicColumns.Add(ColumnEh);
  ColumnEh.FieldName := Field.FieldName;
end;

procedure TLGTAnalysisForm.CreateDynamicFields;
var
  MonthsCount: Integer;
  FirstMonthBegin: Integer;
  Year, Month, Day: Word;
  I: Integer;
  FloatField: TFloatField;
  CurMonth: TDateTime;
  TitleCaption: string;
  FieldName: string;
begin
  FirstMonthBegin := Trunc(FDateBegin);
  DecodeDate(FDateBegin, Year, Month, Day);
  FStartPeriodOffset := Year * 12 + Month;
  DecodeDate(FDateEnd, Year, Month, Day);
  MonthsCount := Year * 12 + Month - FStartPeriodOffset + 1;
  SetLength(FSumQty, MonthsCount);
  CurMonth := FirstMonthBegin;
  for I := 0 to MonthsCount - 1 do
  begin
    TitleCaption := 'Потребность|' + IntToStr(YearOf(CurMonth)) + '|' + FormatSettings.LongMonthNames[MonthOf(CurMonth)];
    FieldName := 'DataField_' + Format('%.2d', [MonthOf(CurMonth)]) + '_' + IntToStr(YearOf(CurMonth));

    FloatField := TFloatField.Create(Self);
    FDynamicFields.Add(FloatField);
    FloatField.FieldName := FieldName;
    FloatField.DisplayLabel := TitleCaption;
    FloatField.DisplayFormat := cstFloatDisplayFormat;
    FloatField.DisplayWidth := cstFloatDisplayWidth;
    FloatField.DataSet := mtMain;
    CreateDynamicColumn(FloatField);

    CurMonth := IncMonth(CurMonth);
  end;

  FloatField := TFloatField.Create(Self);
  FDynamicFields.Add(FloatField);
  FloatField.FieldName := 'DataField_Total';
  FloatField.DisplayLabel := 'Потребность|Итого';
  FloatField.DisplayFormat := cstFloatDisplayFormat;
  FloatField.DisplayWidth := cstFloatDisplayWidth;
  FloatField.DataSet := mtMain;
  CreateDynamicColumn(FloatField);
  FTotalField := FloatField;
end;

function TLGTAnalysisForm.GetDynamicFieldIndex(const ADate: TDateTime): Integer;
var
  Year, Month, Day: Word;
begin
  DecodeDate(ADate, Year, Month, Day);
  Result := Year * 12 + Month - FStartPeriodOffset;
end;

procedure TLGTAnalysisForm.ddMainReadRecord(DataDriver: TDataDriverEh;
  MemTableData: TMemTableDataEh; MemRec: TMemoryRecordEh;
  var ProviderEOF: Boolean);
var
  CuratorId, LotId: Integer;
  DynFieldIdx: Integer;
  TotalOpened: Double;
  Opened: Double;
  Rec: TPrimaryKey;
  ReserveQty, StockQty, PurchaseQty, ClosedQty: Double;
  Keys: TArray<Integer>;

  procedure FillStaticFields1;
  begin
    MemRec.Value[mtMainmaterial_id.Index, dvvValueEh] := fdqMaindm_material_id.Value;
    MemRec.Value[mtMainmaterial_code.Index, dvvValueEh] := fdqMainmt_code.Value;
    MemRec.Value[mtMainmaterial_name.Index, dvvValueEh] := fdqMainmt_name.Value;
    MemRec.Value[mtMainunit_id.Index, dvvValueEh] := fdqMaindm_unit_id.Value;
    MemRec.Value[mtMainunit_abbr.Index, dvvValueEh] := fdqMainunt_abbr.Value;
  end;

  procedure CollectDemands;
  begin
    while not fdqMain.Eof and (Rec.MaterialId = fdqMaindm_material_id.Value) and (Rec.UnitId = fdqMaindm_unit_id.Value) do
    begin
      DynFieldIdx := GetDynamicFieldIndex(fdqMaindm_date.AsDateTime); // <- По дате вычисляем индекс
      FSumQty[DynFieldIdx] := FSumQty[DynFieldIdx] + fdqMaindm_qty.Value;
      ClosedQty := ClosedQty + fdqMaindm_factqty.Value;
      fdqMain.Next;
    end;
  end;
  
  procedure FillData1;
  var
    I: Integer;
  begin
    for I := 0 to High(FSumQty) do
    begin
      if (FSumQty[I] <> 0.0) then
        MemRec.Value[FDynamicFields[I].Index, dvvValueEh] := FSumQty[I]; // <- FDynamicFields[I] = TFoatField
      TotalOpened := TotalOpened + FSumQty[I];
    end;
    if (TotalOpened <> 0.0) then
      MemRec.Value[FTotalField.Index, dvvValueEh] := TotalOpened;
    if (ClosedQty <> 0.0) then
      MemRec.Value[FClosedField.Index, dvvValueEh] := ClosedQty;
    Opened := TotalOpened - ClosedQty;
    if Opened <> 0.0 then
      MemRec.Value[FOpenedField.Index, dvvValueEh] := Opened;
  end;

begin
  inherited;
  ProviderEOF := fdqMain.Eof;
  if ProviderEOF then
    Exit;
  if not fdqMain.Eof then
  begin
    FillStaticFields1;
    ResetSumAccumulators;
    Rec.MaterialId := fdqMaindm_material_id.Value;
    Rec.UnitId := fdqMaindm_unit_id.Value;
    CollectDemands;
    TotalOpened := 0.0;
    FillData1;
  end;
end;

 TMyWorkingTimeCalendarEh = class(TWorkingTimeCalendarEh)
  private
    fdqSpecDays :TFDQuery;
    fdqSpecDayswc_date :TSQLTimeStampField;
    fdqSpecDayswc_holiday :TBooleanField;
    fdqSpecDayswc_preholiday :TBooleanField;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    function IsWorkday(ADate: TDateTime): Boolean; override;
    //procedure GetWorkingTime(ADate: TDateTime; var ATimeRanges: TTimeRangesEh); virtual;
  end;

constructor TMyWorkingTimeCalendarEh.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  fdqSpecDays := TFDQuery.Create(Self);
  fdqSpecDays.Connection := dm3.fdcon;
  fdqSpecDays.Open('SELECT wc_date, wc_holiday, wc_preholiday FROM com_workcalendar');
  fdqSpecDayswc_date := (fdqSpecDays.Fields[0] as TSQLTimeStampField);
  fdqSpecDayswc_holiday := (fdqSpecDays.Fields[1] as TBooleanField);
  fdqSpecDayswc_preholiday := (fdqSpecDays.Fields[2] as TBooleanField);
  fdqSpecDays.IndexFieldNames := 'wc_date';
end;

destructor TMyWorkingTimeCalendarEh.Destroy;
begin
  fdqSpecDayswc_date := nil;
  fdqSpecDayswc_holiday := nil;
  fdqSpecDayswc_preholiday := nil;
  FreeAndNil(fdqSpecDays);
  inherited Destroy;
end;

function TMyWorkingTimeCalendarEh.IsWorkday(ADate: TDateTime): Boolean;
var
  WeekDay: TWeekDayEh;
begin
  ADate := Trunc(ADate);
  WeekDay := DateToWeekDayEh(ADate);
  Result := WeekDay in EhLibManager.WeekWorkingDays;
  if fdqSpecDays.Locate('wc_date', ADate, []) then
  begin
    Result := not fdqSpecDayswc_holiday.Value;
  end;
end;


RegisterGlobalWorkingTimeCalendar(TMyWorkingTimeCalendarEh.Create(nil)).Free;

TMyWorkingTimeCalendarEh = class(TWorkingTimeCalendarEh)
  private
    FHolidays: TDictionary<Integer,Boolean>;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    function IsWorkday(ADate: TDateTime): Boolean; override;
    procedure Refresh;
  end;

constructor TMyWorkingTimeCalendarEh.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FHolidays := TDictionary<Integer,Boolean>.Create;
  Refresh;
end;

destructor TMyWorkingTimeCalendarEh.Destroy;
begin
  FHolidays.Free;
  inherited Destroy;
end;

function TMyWorkingTimeCalendarEh.IsWorkday(ADate: TDateTime): Boolean;
var
  WeekDay: Word;
begin
  if FHolidays.TryGetValue(Trunc(ADate), Result) then
  begin
    Result := not Result;
  end else
  begin
    WeekDay := DayOfWeek(ADate);
    Result := (WeekDay > 1) and (WeekDay < 7);
  end;
end;

procedure TMyWorkingTimeCalendarEh.Refresh;
var
  fdqSpecDays :TFDQuery;
  fdqSpecDayswc_date :TSQLTimeStampField;
  fdqSpecDayswc_holiday :TBooleanField;
begin
  FHolidays.Clear;
  fdqSpecDays := TFDQuery.Create(Self);
  try
    fdqSpecDays.Connection := dm3.fdcon;
    fdqSpecDays.Open('SELECT wc_date, wc_holiday FROM com_workcalendar');
    fdqSpecDayswc_date := (fdqSpecDays.Fields[0] as TSQLTimeStampField);
    fdqSpecDayswc_holiday := (fdqSpecDays.Fields[1] as TBooleanField);
    while not fdqSpecDays.Eof do
    begin
      FHolidays.Add(Trunc(fdqSpecDayswc_date.AsDateTime), fdqSpecDayswc_holiday.Value);
      fdqSpecDays.Next;
    end;
    fdqSpecDays.Close;
  finally
    fdqSpecDays.Free;
  end;
end;