Люди, спасибо вам за помощь, за примеры...
Вы поймите, я хочу овладеть потоками... А вы мне таски предлагаете. Я впервые слышу о них.. Сейчас конечно почитал о них, что-то понял, что-то нет...
При всём уважении, ребята, вопрос не о том, чем лучше чекать прокси. Да сами прокси это просто пример.
Вопрос о потоках.
Смотри... Поток - это инструмент, с помощью которого
асинхронно решают какие-то задачи...
У тебя задача проверить прокси, значит используя поток, ты можешь выполнить проверку асинхронно по отношению к коду, в котором вызываешь проверку.
В этом случае поток должен решать ровно одну задачу, проверка ровно одного прокси. Просто в Delphi изначально сделали какой-то монстроузорный вариант с отдельным классом. Что вводит в заблуждение, когда надо именно выполнить работу асинхронно.
А это значит, что если у тебя список из 100 прокси, то тебе придется для каждой проверки создавать поток, выполнять работу и уничтожать...
Идем дальше.. Вариант с созданием и уничтожением 100 потоков так себе... слишком много ресурсов системы будет затрачено на создание и уничтожение потоков... Поэтому приходит в голову решение, а не создать ли 5-10 потоков, в которых и будет проверка этих 100 прокси... И тут мы приходим к пониманию, что нам надо пул потоков... И сами потоки уже не являются средством решения нашей задачи проверки... Они просто инструмент с помощью которого мы будем решать нашу задачу проверки 100 прокси.. Поэтому появляется новая абстракция - таски... Тебе важно выполнить задачу асинхронно... А уже как она будет сделана - неважно.. с помощью отдельного потока или в том же или еще как, это уже задача другого уровня.
Но если хочется именно велосипеда... Писать свой пул потоков нет ни желания ни понимания... То можно на коленке с имитировать это примерно так...
Тогда твоя задача немного перефразируется...
При этом уже есть куча примитивов которые позволяют это сделать намного удобнее чем использование TStrinList. Например TQueue<T>
Мне надо несколько потоков, которые будут разбирать очередь в которой лежат прокси и проверять их.
Тогда реализация уже перефразированной задачи, с использованием концепции класса потока в Delphi, без примитивов ожидания будет выглядеть так...
Важно, предлагаемый вариант ужасен именно с точки зрения применения современных подходов (когда не нужно знать как работает под капотом, а важнее знать как решать задачи с использованием той или этой технологии), но на коленке понять как работают потоки пойдет...
1.
2.
3.
4.
5.
6.
7.
8.
9.
10.
11.
12.
13.
14.
15.
16.
17.
18.
19.
20.
21.
22.
23.
24.
25.
26.
27.
28.
29.
30.
31.
32.
33.
34.
35.
36.
37.
38.
39.
40.
41.
42.
43.
44.
45.
46.
47.
48.
49.
50.
51.
52.
53.
54.
55.
56.
57.
58.
59.
60.
61.
62.
63.
64.
65.
66.
67.
68.
69.
70.
71.
72.
73.
74.
75.
76.
77.
78.
79.
80.
81.
82.
83.
84.
85.
86.
87.
88.
89.
90.
91.
92.
93.
94.
95.
96.
97.
98.
99.
100.
101.
102.
103.
104.
105.
106.
107.
108.
109.
110.
111.
112.
113.
114.
115.
116.
117.
118.
119.
120.
121.
122.
123.
124.
125.
126.
127.
128.
129.
130.
131.
132.
133.
134.
135.
136.
137.
unit Unit1;
interface
uses
Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, Vcl.Graphics,
Vcl.Controls, Vcl.Forms, Vcl.Dialogs, Vcl.StdCtrls, System.Generics.Collections, System.SyncObjs;
type
TForm1 = class(TForm)
Button1: TButton;
Memo1: TMemo;
procedure FormCreate(Sender: TObject);
procedure FormDestroy(Sender: TObject);
procedure Button1Click(Sender: TObject);
private
const
MAXTHREAD = 10;
var
FThreads: TObjectList<TThread>; // Список потоков
FProxyList: TStringList; // Если хочется головной боли, то пусть будет стринглист
FCounter: Int32; // Счетчик обработки
procedure Log(const aValue: string);
public
{ Public declarations }
end;
TCallbackLog = reference to procedure(const aValue: string);
TThreadProxyCheck = class(TThread)
private
FList: TStringList;
FCounter: PInteger;
FCallback: TCallbackLog;
protected
procedure Execute; override;
public
constructor Create(const aList: TStringList; const aCounter: PInteger; const aCallback: TCallbackLog);
end;
var
Form1: TForm1;
implementation
{$R *.dfm}
{ TThreadProxyCheck }
constructor TThreadProxyCheck.Create(const aList: TStringList; const aCounter: PInteger; const aCallback: TCallbackLog);
begin
FList := aList;
FCounter := aCounter; // Передаем указатель, чтобы не использовать глобальные переменные
FCallback := aCallback; // вывод в лог
inherited Create(True);
end;
procedure TThreadProxyCheck.Execute;
var
Index: Int32;
LValue, RValue: string;
ID: TThreadID;
begin
while not Terminated do // Работаем, пока не будет указано о завершении
begin
// В идеале должен быть примитив вроде TEvent/TMonitor, чтобы зря не крутился цикл
if Index >= FList.Count - 1 then // Нужно перед Increment, чтобы не вызывать рост счетчика
begin
TInterlocked.Exchange(Index, FCounter^); // Обязательно нужно, чтобы поймать сброшенный счетчик
Continue;
end;
Index := TInterlocked.Increment(FCounter^);
if Index >= FList.Count - 1 then
Continue;
var Value := FList.Strings[Index];
var Separator := Value.IndexOf(':');
LValue := Value.Substring(0, Separator);
RValue := Value.Substring(Separator + 1);
// Чекаем прокси
// CheckProxy(LValue, RValue);
ID := ThreadID;
TThread.Synchronize( // в данном случае нужен только для того чтобы вывести лог, а так вся работа идет параллельно.
Self,
procedure
begin
FCallback(ID.ToString() + ': ' + LValue + ' = ' + RValue);
end
);
end;
end;
procedure TForm1.Button1Click(Sender: TObject);
begin
FCounter := -1;
end;
procedure TForm1.FormCreate(Sender: TObject);
begin
ReportMemoryLeaksOnShutdown := True;
FProxyList := TStringList.Create();
FThreads := TObjectList<TThread>.Create();
// Важно, кол-во элементов в списке будет всегда 100, и сами элементы не будут изменяться пока работают потоки
// Поэтому доступ к ним не будем синхронизировать
for var k := 1 to 100 do
FProxyList.Add(Random(100).ToString() + ':' + (k * k).ToString());
// По умолчанию работы не будет
FCounter := FProxyList.Count + 1;
// будет 10 потоков, которые будут чекать прокси
for var k := 1 to MAXTHREAD do
FThreads.Add(TThreadProxyCheck.Create(FProxyList, @FCounter, Log));
for var k := 0 to MAXTHREAD - 1 do
FThreads.Items[k].Start();
end;
procedure TForm1.FormDestroy(Sender: TObject);
begin
FThreads.Free();
FProxyList.Free();
end;
procedure TForm1.Log(const aValue: string);
begin
Memo1.Lines.Add(aValue);
end;
end.
Заметь, ни одной глобальной переменной кроме стандартной, и то к ней нет обращения...
