unit tvMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, ComCtrls, CommCtrl, StdCtrls;

const
  WM_STATECHANGED = WM_APP + $0010;

type
  TForm1 = class(TForm)
    TreeView1: TTreeView;
    Memo1: TMemo;
    procedure FormCreate(Sender: TObject);
    procedure TreeView1Click(Sender: TObject);
  private
    procedure WMStateChanged(var Msg: TMessage); message WM_STATECHANGED;
  public
    { Public declarations }
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

procedure TForm1.FormCreate(Sender: TObject);
var
  TVStyle: Cardinal;
begin
  TVStyle := GetWindowLong(TreeView1.Handle, GWL_STYLE);
  SetWindowLong(TreeView1.Handle, GWL_STYLE, TVStyle or TVS_CHECKBOXES);
  TreeView1.Items[0].Expand(True);
  TreeView1.Items[5].Expand(True);
  TreeView1.Items[0].StateIndex := 0;
  TreeView1.Items[1].StateIndex := 0;
  TreeView1.Items[2].StateIndex := 0;
  TreeView1.Items[5].StateIndex := 0;
end;

procedure TForm1.TreeView1Click(Sender: TObject);
var
  dwPos: Cardinal;
  HitTest: TTVHitTestInfo;
begin
  dwPos := GetMessagePos;
  HitTest.pt.X := TSmallPoint(dwPos).x;
  HitTest.pt.Y := TSmallPoint(dwPos).y;
  MapWindowPoints(HWND_DESKTOP, TreeView1.Handle, HitTest.pt, 1);
  TreeView_HitTest(TreeView1.Handle, HitTest);
  if HitTest.flags and TVHT_ONITEMSTATEICON <> 0 then
    PostMessage(Handle, WM_STATECHANGED, 0, LPARAM(HitTest.hItem));
end;

procedure TForm1.WMStateChanged(var Msg: TMessage);
var
  Node: TTreeNode;
  State: DWord;
begin
  State := TreeView_GetCheckState(TreeView1.Handle, HTREEITEM(Msg.LParam));
  Node := TreeView1.Items.GetNode(HTREEITEM(Msg.LParam));
  Memo1.Lines.Add(Format('Node %s state changed to %d.', [Node.Text, State]));
end;

end.