procedure TForm1.btnGoClick(Sender: TObject);
const
  BUF_SIZE = 1024*2; // Размер буфера для чтения выходных данных блоками
  ConstFormatStr = '%d. ~ %s';//строка формата для подстановки вывода текста в мемо
var
{$IFDEF MSWINDOWS}
Buffer: RawByteString = '';
BufferStg: RawByteString = '';//буфер-накопитель
{$ENDIF}
{$IFDEF UNIX}
Buffer: String = '';
BufferStg: String = '';//буфер-накопитель
{$ENDIF}
  StrCounter: Integer = 0;//счетчик выводимых memoOutput строк
  BytesRead: LongInt = 0;//кол-во считанных из буфера байт
  LineEndingPos_13: Integer = 0;//позиция символа возврата каретки #13(CR)
  LineEndingPos_10: Integer = 0;//позиция символа перевода строки #10(CR)
  dt: TDateTime;
begin
  memoOutput.Clear;

  {$IFDEF MSWINDOWS}
  // В Windows команду dir нельзя использовать напрямую, потому что она является встроенной
  // командой оболочки. Поэтому нужны cmd.exe и дополнительные параметры
  AProcess.Executable := 'c:\windows\system32\cmd.exe';
  AProcess.Parameters.Add('/c');
  AProcess.Parameters.Add('dir /s c:\windows\system32');
  {$ENDIF}
  {$IFDEF UNIX}
  AProcess.Executable := '/bin/ls';
  AProcess.Parameters.Add('--recursive');
  AProcess.Parameters.Add('--all');
  AProcess.Parameters.Add('-l');
  {$ENDIF}

  AProcess.Options := [poUsePipes, poStderrToOutPut, poNoConsole];

  //Запуск процесса (выполнение команды dir/ls)
  AProcess.Execute;

  dt:= Now;
  memoOutput.Lines.Add('==== процесс начат: ' + FormatDateTime('dd.mm.yyyy h:mm:ss:zzz am/pm',dt) + ' ====');
  memoOutput.Lines.Add('');

  SetLength(Buffer,BUF_SIZE);//задаем минимальный размер Buffer (как правило размер Pipes в ОС не превышает 2kB)
  BytesRead:= AProcess.Output.Read(Buffer[1],Length(Buffer));//читаем в Buffer и получаем кол-во считанных байт BytesRead;

  repeat
    memoOutput.Lines.BeginUpdate;
    try
      if BytesRead > 0 then
      begin
        SetLength(Buffer,BytesRead);

        {LineEnding - алиас для sLineBreak:
        Win = #13#10
        Unix = #10
        Mac OS до v.9 = #13}

        {$IFDEF MSWINDOWS}
        //получаем позицию #13 в строке
        LineEndingPos_13:= Pos(#13,Buffer);

        repeat
          case LineEndingPos_13 of
            0:
              begin
                BufferStg:= BufferStg + Buffer;
              end;
            1://#13 в начале строки
              begin
                LineEndingPos_10:= Pos(#10, Buffer);

                case (LineEndingPos_10 - LineEndingPos_13) of
                  1: //#10(LF) следует за #13(CR)
                    begin
                      Inc(StrCounter);
                      //сбрасываем буфер-хранилище в memo...
                      memoOutput.Lines.Add(Format(ConstFormatStr,[StrCounter,WinCPToUTF8(BufferStg)]));

                      //очищаем буфер-хранилище
                      BufferStg:='';

                      //откусываем от начала буфера символы перевода строки #13#10(CRLF)
                      Delete(Buffer,1,2); //... и крутим цикл дальше
                    end;
                  else //после #13(CR) следует любой символ, кроме #10(LF), или нет вообще символов
                    begin
                      //клеим символ возврата каретки #13(CR) к буферу-накопителю
                      BufferStg:= BufferStg + #13;

                      //откусываем от начала буфера символ возврата каретки #13(CR)
                      Delete(Buffer,1,1); //... и крутим цикл дальше
                    end;
                  end;
              end;
            else //#13(CR) в середине или в конце буфера
              LineEndingPos_10:= Pos(#10, Buffer);
              case (LineEndingPos_10 - LineEndingPos_13) of
                1: //#10(LF) следует за #13(CR)
                  begin
                    //копируем часть буфера до #13(CR) в буфер-хранилище
                    BufferStg:= BufferStg + Copy(Buffer,1,LineEndingPos_13 - 1);

                    Inc(StrCounter);

                    //сбрасываем буфер-хранилище в memo...
                    memoOutput.Lines.Add(Format(ConstFormatStr,[StrCounter,WinCPToUTF8(BufferStg)]));

                    //очищаем буфер-хранилище
                    BufferStg:='';

                    //отрезаем спереди часть буфера вместе BufferStg + символами перевода строки #13#10(CRLF)
                    Delete(Buffer,1, LineEndingPos_13 + 1);//... и крутим цикл дальше
                  end;
                else //после #13(CR) следует любой символ, кроме #10(LF), или нет вообще символов
                  begin
                    //клеим его к буферу-накопителю
                    BufferStg:= BufferStg + #13;

                    //откусываем от начала буфера символ возврата каретки #13(CR)
                    Delete(Buffer,1,1);//... и крутим цикл дальше
                  end;
              end;
          end;
          LineEndingPos_13:= Pos(#13,PChar(Buffer));
        until LineEndingPos_13 = 0;
        {$ENDIF}
        {$IFDEF UNIX}
        //получаем позицию #10 в строке
        LineEndingPos_10:= Pos(#10,Buffer);

        repeat
          case LineEndingPos_10 of
            0:
              begin
                BufferStg:= BufferStg + Buffer;
              end;
            1: //#10 в начале строки
              begin
                Inc(StrCounter);
                //сбрасываем буфер-хранилище в memo...
                memoOutput.Lines.Add(Format(ConstFormatStr,[StrCounter,BufferStg]));

                //очищаем буфер-хранилище
                BufferStg:='';

                //откусываем от начала буфера символ перевода строки #10(LF)
                Delete(Buffer,1,1);

                //... и крутим цикл дальше
              end
            else //#10(LF) в середине или в конце буфера
              begin
                //копируем часть Buffer до #10(LF) в буфер-накопитель
                BufferStg:= BufferStg + Copy(Buffer,1,LineEndingPos_10 - 1);

                Inc(StrCounter);
                //сбрасываем буфер-хранилище в memo...
                memoOutput.Lines.Add(Format(ConstFormatStr,[StrCounter,BufferStg]));


                //очищаем буфер-хранилище
                BufferStg:='';

                //отрезаем спереди часть буфера вместе BufferStg + символом перевода строки #10(LF)
                Delete(Buffer,1,LineEndingPos_10);

                //... и крутим цикл дальше
              end;
          end;
          LineEndingPos_10:= Pos(#10,Buffer);
        until LineEndingPos_10 = 0;
        {$ENDIF}
      end;
    finally
      memoOutput.Lines.EndUpdate;
      memoOutput.SelStart := UTF8Length(memoOutput.Text);
    end;
    Sleep(10);
    Application.ProcessMessages;

    SetLength(Buffer,BUF_SIZE);
    BytesRead:= AProcess.Output.Read(Buffer[1],Length(Buffer));//читаем в Buffer и получаем кол-во считанных байт BytesRead;
  until BytesRead = 0;

  //сливаем остатки буфера-накопителя в Мемо
  if Length(BufferStg) > 0 then
  begin
    Inc(StrCounter);
    //сбрасываем буфер-хранилище в memo...
    {$IFDEF MSWINDOWS}
    memoOutput.Lines.Add(Format(ConstFormatStr,[StrCounter,BufferStg]));
    {$ENDIF}
    {$IFDEF UNIX}
    memoOutput.Lines.Add(Format(ConstFormatStr,[StrCounter,BufferStg]));
    {$ENDIF}

  end;
  dt:= Now;
  memoOutput.Lines.Add('');
  memoOutput.Lines.Add('==== процесс закончен: ' + FormatDateTime('dd.mm.yyyy h:mm:ss:zzz am/pm',dt) + ' ====');
end;