//-----------------------------------
 type
  TRecordIBQuery = class
    ID      :integer;
    ID_PARENT :integer;
    TEXT    :string;
    ID_ICO  :integer;
  end;

procedure Creat_Items_To_Treeviwe(perIBQuery :TIBQuery; perTreeView :TTreeView; perTreeName:string);
var
  Node :TTreeNode;
  recIB :TRecordIBQuery;
  Lost :TObjectList;

  function GetRecIB():TRecordIBQuery;
  begin
    result:=TRecordIBQuery.Create;
    result.ID:=perIBQuery.FieldByName('ID').AsInteger;
    result.ID_PARENT:=perIBQuery.FieldByName('ID_PARENT').AsInteger;
    result.TEXT:=trim(perIBQuery.FieldByName('TEXT').AsString);
    result.ID_ICO:=perIBQuery.FieldByName('ID_ICO').AsInteger;
  end;

  function FindParent(idPar :integer):TTreeNode;                                //поиск родителя
  var i :integer;
  begin
    for i:=0 to perTreeView.Items.Count-1 do begin
      result:=perTreeView.Items[i];
      if integer(result.Data) = idPar then begin
        exit;
      end;
    end;
    result:=nil;
  end;

  procedure DoLost();
  var i :integer;
  begin
    for i:=Lost.Count-1 downto 0 do begin
      recIB:=TRecordIBQuery(Lost[i]);
      Node:=FindParent(recIB.ID_PARENT); //родитель уже создан?
      if Node <> nil then begin
        Node:=perTreeView.Items.AddChildObject(Node, recIB.TEXT, pointer(recIB.ID));
        Node.ImageIndex:=recIB.ID_ICO;
        Node.SelectedIndex:=recIB.ID_ICO;
        Lost.Delete(i); //удаляем из списка потерянных, объект recIB освобождается автоматом
      end;
    end;
  end;

begin
  Lost:=TObjectList.Create;                                                     //создаем список для потерянных узлов
  try
    perIBQuery.Active:=false;                                                   //деактивируем запрос
    perIBQuery.SQL.Text:='select * from '+perTreeName+' ORDER BY ID_PARENT, POSITION_ ASC';             //запрос вся таблица дерева по порядку с первого номера
    perIBQuery.Active:=true;                                                    //активируем запрос
    while not perIBQuery.Eof do begin                                           //пошли в цыкл по запросу
      recIB:=GetRecIB();                                                        //копируем данные записи в вспомогательный класс , который создается в функции
      if recIB.ID_PARENT = 0 then begin                                         //если запись не имеет родителя то это корень , т.е. самый главный родитель
        Node:=perTreeView.Items.AddObject(nil, recIB.TEXT, pointer(recIB.ID));  //пишем его в дерево присваивая порядковый номер в  pointer
        Node.ImageIndex:=recIB.ID_ICO;
        Node.SelectedIndex:=recIB.ID_ICO;
        recIB.Free;                                                             //не забываем освобождать память от уже ненужного объекта
      end else begin                                                            //родитель должен быть
        Node:=FindParent(recIB.ID_PARENT);                                      //родитель уже создан?
        if Node = nil then begin                                                //не нашли
          Lost.Add(recIB);                                                      //запоминаем данные
        end else begin                                                          //цепляемся к родителю
          Node:=perTreeView.Items.AddChildObject(Node, recIB.TEXT, pointer(recIB.ID));
          Node.ImageIndex:=recIB.ID_ICO;
          Node.SelectedIndex:=recIB.ID_ICO;
          recIB.Free;                                                           //не забываем освобождать память от уже ненужного объекта
        end;
      end;
      perIBQuery.Next;
    end;
    //окучиваем потерянные объекты
    while Lost.Count > 0 do DoLost();
  finally
    Lost.Free;
  end;
end;