unit Thread.Basic;

interface

uses
  System.Classes, System.SysUtils, System.Variants;

type
  TBasicThread = class(TThread)
  private
    FOnSuccess: TNotifyEvent;
    FOnExecute: TNotifyEvent;
    FOnError: TNotifyEvent;
    FErrorMessage: string;
    FThreadResult: Variant;
  protected
    procedure HandleException(const AErrorMessage:string);
    procedure DoOnExecute; virtual;
    procedure DoOnError; virtual;
    procedure DoOnSuccess; virtual;
    procedure InternalExecute; virtual;
    procedure Execute; override;
  public
    property OnExecute:TNotifyEvent read FOnExecute write FOnExecute;
    property OnError:TNotifyEvent read FOnError write FOnError;
    property OnSuccess:TNotifyEvent read FOnSuccess write FOnSuccess;
    property ErrorMessage:string read FErrorMessage;
    property ThreadResult:Variant read FThreadResult write FThreadResult;
    class function StartThread(AOnExecute, AOnSuccess, AOnError:TNotifyEvent):TBasicThread; overload;
  end;

implementation

{ BasicThread }

class function TBasicThread.StartThread(AOnExecute, AOnSuccess, AOnError: TNotifyEvent): TBasicThread;
begin
 Result:=TBasicThread.Create(True);
 Result.OnError:=AOnError;
 Result.OnSuccess:=AOnSuccess;
 Result.OnExecute:=AOnExecute;
 Result.FreeOnTerminate:=True;
 Result.Start;
end;

procedure TBasicThread.DoOnError;
begin
 if Assigned(OnError) and (not Terminated) then
  OnError(Self);
end;

procedure TBasicThread.DoOnExecute;
begin
 if Assigned(OnExecute) and (not Terminated) then
  OnExecute(Self);
end;

procedure TBasicThread.DoOnSuccess;
begin
  if Assigned(OnSuccess) and (not Terminated) then
   OnSuccess(Self);
end;

procedure TBasicThread.Execute;
begin
 InternalExecute;
end;


procedure TBasicThread.HandleException(const AErrorMessage: string);
begin
 FErrorMessage:=AErrorMessage;
 Synchronize(DoOnError);
end;

procedure TBasicThread.InternalExecute;
begin
 try
  DoOnExecute;
  Synchronize(DoOnSuccess);
 except on E:Exception do
  HandleException(E.Message);
 end;
end;

end.

private
   FBasicThread: TBasicThread;
   procedure OnThreadError(Sender:TObject);
   procedure OnThreadSuccess(Sender:TObject);
   procedure OnThreadExecute(Sender:TObject);

...

procedure TForm1.Button1Click(Sender: TObject);
begin
 if not Assigned(FBasicThread) then
  begin
   FBasicThread:=TBasicThread.StartThread(OnThreadExecute, OnThreadSuccess, OnThreadError);
   Button1.Enabled:=False;
  end;
end;

procedure TForm1.OnThreadError(Sender: TObject);
begin
 Label1.Font.Color:=clRed;
 Label1.Caption:=FBasicThread.ErrorMessage;
 FBasicThread:=nil;
 Button1.Enabled:=True;
end;

procedure TForm1.OnThreadExecute(Sender: TObject);
var
 AResult:Integer;
begin
 Randomize;
 Sleep(1000);
 AResult:=Random(100);
 if AResult>50 then
  raise Exception.CreateFmt('Error executing thread %d', [AResult])
   else
  FBasicThread.ThreadResult:=string.Format('Hello world, %d',[AResult]);
end;

procedure TForm1.OnThreadSuccess(Sender: TObject);
begin
 Label1.Font.Color:=clGreen;
 Label1.Caption:=VarToStr(FBasicThread.ThreadResult);
 FBasicThread:=nil;
 Button1.Enabled:=True;
end;