function FindGraphicClass(const Buffer; const BufferSize: Int64;
out GraphicClass: TGraphicClass): Boolean;
var
  LongWords: array[Byte] of LongWord absolute Buffer;
  Words: array[Byte] of Word absolute Buffer;
begin
  GraphicClass := nil;
  Result := False;
  if BufferSize < MinGraphicSize then Exit;
  case Words[0] of
    $4D42: GraphicClass := TBitmap;
    $D8FF: GraphicClass := TJPEGImage;
    $4949: if Words[1] = $002A then GraphicClass := TWicImage; //i.e., TIFF
    $4D4D: if Words[1] = $2A00 then GraphicClass := TWicImage; //i.e., TIFF
  else
  if Int64(Buffer) = $A1A0A0D474E5089 then
    GraphicClass := TPNGImage
  else if LongWords[0] = $9AC6CDD7 then
    GraphicClass := TMetafile
  else if (LongWords[0] = 1) and (LongWords[10] = $464D4520) then
    GraphicClass := TMetafile
  else if StrLComp(PAnsiChar(@Buffer), 'GIF', 3) = 0 then
    GraphicClass := TGIFImage
  else if Words[1] = 1 then
    GraphicClass := TIcon;
  end;
  Result := (GraphicClass <> nil);
end;

  function OpenGraphic( aData: TSTream; out aExt: String): TGraphic;
  const
    ImageClassses:   array[0..3] of TGraphicClass = ( TJPEGImage, TPngImage, TGIFImage, TBitmap);
    ImageExtensions: array[0..3] of String = ( '.jpg', '.png', '.gif', '.bmp');
  var
    i: Integer;
  begin
    Result := nil;
    for i := 0 to Length(ImageClassses)-1 do
    try
      Result := ImageClassses[i].Create;
      aData.Position := 0;
      Result.LoadFromStream(aData);
      aExt := ImageExtensions[i];
      break;
    except
      Result := nil;
    end;
  end;