{ получение или возвращение привилегий на блокировку физических страниц }
function SetLockPagesPrivilege(Process: THANDLE; Enable: Boolean): Boolean;
const
     SE_LOCK_MEMORY_NAME = 'SeLockMemoryPrivilege';
type
    DWORDPTR = ^DWORD;
var
   Token: THANDLE;
   Info: TTokenPrivileges;
begin
     // открыть токен
     Result := OpenProcessToken(Process, TOKEN_ADJUST_PRIVILEGES, Token);
     if not Result then Exit;

     try
        // enable или disable
        Info.PrivilegeCount := 1;
        if Enable then
          Info.Privileges[0].Attributes := SE_PRIVILEGE_ENABLED
        else
          Info.Privileges[0].Attributes := 0;

        // получить LUID
        Result := LookupPrivilegeValue(nil, SE_LOCK_MEMORY_NAME, Info.Privileges[0].Luid);
        if not Result then Exit;

        // привилегии
        Result := AdjustTokenPrivileges(Token, False, Info, 0, PTokenPrivileges(nil)^, DWORDPTR(nil)^);
        if not Result then Exit;

        Result := GetLastError = ERROR_SUCCESS;
     finally
       CloseHandle(Token);
     end;  
end;

{ резервирование физической памяти (вернет 0, если неудачно) }
function AllocPhysicalMemory(Size: LongWord): LongWord;
var
   PageCount: LongWord;
   MemoryItem: PMemoryItem;
begin
     Result := 0;

     if not SetLockPagesPrivilege(GetCurrentProcess, True) then Exit;

     PageCount := Size div PageSize;
     if Size mod PageSize <> 0 then Inc(PageCount);

     MemoryItem := AllocMem(8 + PageCount * SizeOf(LongWord));
     if MemoryItem = nil then Exit;

     try
        { резервирование физической памяти }
        MemoryItem.PageCount := PageCount;
        if not AllocateUserPhysicalPages(GetCurrentProcess, PageCount, @MemoryItem.Pages[0])
         then Exit;

        { проверка, все ли страницы зарезервированы }
        if PageCount <> MemoryItem.PageCount then
         begin
              FreeUserPhysicalPages(GetCurrentProcess, PageCount, @MemoryItem.Pages[0]);
              Exit;
         end;

        Result := LongWord(MemoryItem);
     finally
       if Result = 0 then FreeMem(MemoryItem);
     end;
end;