// Разбивает разделителем BreakStr строку SLine на список строк с максимальной длиной MaxCol,
// выполняя поиск 1-го попавшегося символа-разделителя (из BreakChars) СЛЕВА от (MaxCol+1)-символа
// (при условии, что еще левее него есть символ-НЕразделитель).
//
// Если символа-разделителя слева не найдено - текущая строка всё равно добавляется в
// результат-список с длиной MaxCol, и происходир разбор следующей строки.
//
// Если следующая (не первая) строка начинается с символов SpaceChars - они будут удалены.
// Если последние строки состоят только из SpaceChars - они не будут добавлены.
function WrapToList( const SLine: String; MaxCol: Integer; const BreakStr: String = sLineBreak; const BreakChars: TSysCharSet = [ ' ', '-', #9, '.', ',', ';' ]; const SpaceChars: TSysCharSet = [ ' ', #9 ] ): String;
var
  i, nFullLength, nStartPos, nFind: Integer;
  bFindNonBreak: Boolean;
begin
  nFullLength := Length( SLine );
  if nFullLength <= MaxCol then begin
    Result := SLine;
    Exit;
  end;

  Result := '';
  if MaxCol <= 0 then
    Exit;

  nStartPos := 1;
  repeat
    if SLine[ nStartPos + MaxCol - 1 ] in BreakChars then begin
      Result := Result + Copy( SLine, nStartPos, MaxCol );
      nStartPos := nStartPos + MaxCol;
    end else begin
      nFind := -1;
      for i := nStartPos + MaxCol - 1 downto nStartPos do if SLine[ i ] in BreakChars then begin
        nFind := i;
        Break;
      end;

      if nFind <> -1 then begin
        bFindNonBreak := False;
        for i := nFind downto nStartPos do if not ( SLine[ i ] in BreakChars ) then begin
          bFindNonBreak := True;
          Break;
        end;
        if not bFindNonBreak then
          nFind := -1;
      end;

      if nFind = -1 then
        nFind := nStartPos + MaxCol - 1;

      Result := Result + Copy( SLine, nStartPos, nFind - nStartPos + 1 );
      nStartPos := nFind + 1;
    end;

    if nFullLength >= nStartPos then begin
      if SpaceChars <> [] then begin
        while ( nFullLength >= nStartPos ) and ( SLine[ nStartPos ] in SpaceChars ) do
          Inc( nStartPos );

        if nFullLength < nStartPos then
          Exit;
      end;

      Result := Result + BreakStr;
      if nFullLength - nStartPos + 1 <= MaxCol then begin
        Result := Result + Copy( SLine, nStartPos, MaxInt );
        Exit;
      end;
    end;
  until nFullLength < nStartPos;
end;

// Разбивает разделителем BreakStr строку SLine на список строк с максимальной длиной MaxCol,
// выполняя поиск 1-го попавшегося символа-разделителя (из BreakChars) СЛЕВА от (MaxCol+1)-символа
// (при условии, что еще левее него есть символ-НЕразделитель).
// Этот поиск выполняется, если MaxCol-символ не разделитель (или следующий за ним символ не из SpaceChars),
// а иначе сразу идет переход на следующую строку
//
// Если символа-разделителя слева не найдено - текущая строка всё равно добавляется в
// результат-список с длиной MaxCol, и происходир разбор следующей строки.
//
// Если следующая (не первая) строка начинается с символов SpaceChars - они будут удалены.
// Если последние строки состоят только из SpaceChars - они не будут добавлены.
function WrapToList( const SLine: String; MaxCol: Integer; const BreakStr: String = sLineBreak; const BreakChars: TSysCharSet = [ ' ', '-', #9, '.', ',', ';' ]; const SpaceChars: TSysCharSet = [ ' ', #9 ] ): String;
var
  i, nFullLength, nStartPos, nFind: Integer;
  bFindNonBreak: Boolean;
begin
  nFullLength := Length( SLine );
  if nFullLength <= MaxCol then begin
    Result := SLine;
    Exit;
  end;

  Result := '';
  if MaxCol <= 0 then
    Exit;

  nStartPos := 1;
  repeat
    if ( SLine[ nStartPos + MaxCol - 1 ] in BreakChars )
       or
       ( SLine[ nStartPos + MaxCol ] in SpaceChars )
    then begin
      Result := Result + Copy( SLine, nStartPos, MaxCol );
      nStartPos := nStartPos + MaxCol;
    end else begin
      nFind := -1;
      for i := nStartPos + MaxCol - 1 downto nStartPos do if SLine[ i ] in BreakChars then begin
        nFind := i;
        Break;
      end;

      if nFind <> -1 then begin
        bFindNonBreak := False;
        for i := nFind downto nStartPos do if not ( SLine[ i ] in BreakChars ) then begin
          bFindNonBreak := True;
          Break;
        end;
        if not bFindNonBreak then
          nFind := -1;
      end;

      if nFind = -1 then
        nFind := nStartPos + MaxCol - 1;

      Result := Result + Copy( SLine, nStartPos, nFind - nStartPos + 1 );
      nStartPos := nFind + 1;
    end;

    if nFullLength >= nStartPos then begin
      if SpaceChars <> [] then begin
        while ( nFullLength >= nStartPos ) and ( SLine[ nStartPos ] in SpaceChars ) do
          Inc( nStartPos );

        if nFullLength < nStartPos then
          Exit;
      end;

      Result := Result + BreakStr;
      if nFullLength - nStartPos + 1 <= MaxCol then begin
        Result := Result + Copy( SLine, nStartPos, MaxInt );
        Exit;
      end;
    end;
  until nFullLength < nStartPos;
end;