procedure TForm1.RestoreColumnsOrder(const Grid: TDbGrid);
var
  R: TRegistry;
  BufSize: Integer;
  Buffer: Pointer;
  Stream: TMemoryStream;
begin
  if Assigned(Grid) then
  begin
    R := TRegistry.Create;
    Stream := TMemoryStream.Create;
    try
      if R.OpenKey('Software\'+Application.Title+'\'+Grid.Owner.Name+'\'+Grid.Name, False) then
      begin
        if R.ValueExists('ColumnsOrder') then
        begin
          BufSize := R.GetDataSize('ColumnsOrder');
          GetMem(Buffer, BufSize);
          try
            R.ReadBinaryData('ColumnsOrder', Buffer^, BufSize);
            Stream.Write(Buffer^, BufSize);
            Stream.Seek( 0 , 0 );
            Grid.Columns.LoadFromStream(Stream);
          finally
            FreeMem(Buffer);
          end;//try
        end;//if
      end;//if
    finally
      Stream.Free;
      R.Free;
    end;//try
  end;//if
end;

procedure TForm1.SaveColumnsOrder(const Grid: TDbGrid);
var
  R: TRegistry;
  Stream: TMemoryStream;
begin
  if Assigned(Grid) then
  begin
    R := TRegistry.Create;
    Stream := TMemoryStream.Create;
    try
      if R.OpenKey('Software\'+Application.Title+'\'+Grid.Owner.Name+'\'+Grid.Name, True) then
      begin
        if R.ValueExists('ColumnsOrder') then R.DeleteValue('ColumnsOrder');
        Grid.Columns.SaveToStream(Stream);
        R.WriteBinaryData('ColumnsOrder', Stream.Memory^, Stream.Size);
      end;//if
    finally
      Stream.Free;
      R.Free;
    end;//try
  end;//if
end;