function HashData( Source: Pointer; nSourceLen: DWORD; Dest: Pointer; nResultLen: DWORD; alg: ALG_ID ): Boolean;
var
  lpProvider: PChar;
  dwProvType: DWORD;

  hash_prov: HCRYPTPROV;
  hash_item: HCRYPTHASH;
  hash_len: DWORD;
begin
  Result := FALSE;

  if ( alg >= CALG_SHA_256 ) and ( alg <= CALG_SHA_512 ) then begin
    lpProvider := nil;
    dwProvType := PROV_RSA_AES;
  end else begin
    lpProvider := MS_DEF_PROV;
    dwProvType := PROV_RSA_FULL;
  end;

  if ( CryptAcquireContext( @hash_prov, nil, lpProvider, dwProvType, CRYPT_VERIFYCONTEXT or CRYPT_SILENT ) <> FALSE ) then
  begin
    if ( CryptCreateHash( hash_prov, alg, nil, 0, @hash_item ) ) then
    begin
      if ( CryptHashData( hash_item, Source, nSourceLen, 0 ) ) then
      begin
        hash_len := nResultLen;
        if ( CryptGetHashParam( hash_item, HP_HASHVAL, Dest, @nResultLen, 0 ) and ( hash_len = nResultLen ) ) then
          Result := TRUE;
      end;
      CryptDestroyHash( hash_item );
    end;
    CryptReleaseContext( hash_prov, 0 );
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
type
  THASH_SHA256_DATA = packed array[ 0 .. 31 ] of Byte;
var
  hash: THASH_SHA256_DATA;
  S, SHex: AnsiString;
begin
  S := 'qwerty';
  if HashData( Pointer( S ), Length( S ), @hash, sizeof( hash ), CALG_SHA256 ) then begin
    SetLength( SHex, 2 * sizeof( hash ) );
    BinToHex( PAnsiChar( @hash ), PAnsiChar( SHex ), sizeof( hash ) );
    ShowMessage( SHex );
  end else
    ShowMessage( 'error' );
end;