library myplugin;

{$mode objfpc}{$H+}
{$message warn 'Check OriginalFilename into version info in project options'}

uses
  // this includes the LCL widgetset
  Interfaces,
  Forms,
  SysUtils,
  Windows,
  // project
  ufmMain;

const
  cDetectStringCmd = 'EXT="TEST" | EXT="TES" | EXT="TST"';
  cDetectStringExt = '.TEST.TES.TST';

procedure ListGetDetectString(DetectString: PChar; MaxLen: Integer); stdcall;
begin
  StrLCopy(DetectString, PChar(cDetectStringCmd), MaxLen);
end;

function FileExtIsFits(FileToLoad: PChar): Boolean;
var
  Ext: string;
begin
  Result := False;
  Ext := ExtractFileExt(string(FileToLoad));
  Ext := UpperCase(Ext);
  Result := (Pos(Ext, cDetectStringExt) > 0);
end;

function ListLoad(ListerWin: HWND; FileToLoad: PChar; ShowFlags: Integer): HWND; stdcall;
begin
  if FileExtIsFits(FileToLoad) then
    Result := TfmMain.PluginShow(ListerWin, string(FileToLoad))
  else
    Result := 0;
end;

function ListLoadNext(ListerWin, PluginWin: HWND; FileToLoad: PChar; ShowFlags: Integer): Integer; stdcall;
begin
  if FileExtIsFits(FileToLoad) then
    Result := TfmMain.PluginShowNext(PluginWin, string(FileToLoad))
  else
    Result := 0;
end;

procedure ListCloseWindow(PluginWin: HWND); stdcall;
begin
  TfmMain.PluginHide(PluginWin);
end;

{ Exprot }

exports
 ListGetDetectString,
 ListLoad,
 ListLoadNext,
 ListCloseWindow;

{$R *.res}

begin
  Application.Initialize;
end.

  TfmMain = class(TForm)
  private
    FTotCmdWin: HWND;    // handle of TotalCommander window
    FParentWin: HWND;    // handle of Lister window
    FQuickView: Boolean; // Ctrl+Q panel
  protected
    procedure CreateParams(var Params: TCreateParams); override;
  public
    constructor CreateParented(AParentWindow: HWND);
  public
    class function PluginShow(ListerWin: HWND; FileToLoad: string): HWND;
    class function PluginShowNext(PluginWin: HWND; FileToLoad: string): Integer;
    class function PluginHide(PluginWin: HWND): HWND;
  end;

implementation

{$R *.lfm}

{ TfmMain }

class function TfmMain.PluginShow(ListerWin: HWND; FileToLoad: string): HWND;
var
  fmMain: TfmMain;
begin
  fmMain := nil;
  try
    fmMain := TfmMain.CreateParented(ListerWin);
    fmMain.Label1.Caption := FileToLoad;
    fmMain.Show;
    SetWindowLong(fmMain.Handle, GWL_USERDATA, PtrInt(fmMain));
    // set focus to our window
    if not fmMain.FQuickView then
    begin
      PostMessage(fmMain.Handle, WM_SETFOCUS, 0, 0);
      fmMain.SetFocus;
    end;
    Result := fmMain.Handle;
  except
    if Assigned(fmMain) then
      fmMain.Free;
    Result := 0;
  end;
end;

class function TfmMain.PluginShowNext(PluginWin: HWND; FileToLoad: string): Integer;
var
  fmMain: TfmMain;
begin
  fmMain := TfmMain(GetWindowLong(PluginWin, GWL_USERDATA));
  try
    fmMain.Label1.Caption := FileToLoad;
    fmMain.Show;
    Result := 0;
  except
    Result := 1;
  end;
end;

class function TfmMain.PluginHide(PluginWin: HWND): HWND;
var
  fmMain: TfmMain;
begin
  Result := 0;
  fmMain := TfmMain(GetWindowLong(PluginWin, GWL_USERDATA));
  try
    fmMain.Free;
  except
  end;
end;

procedure TfmMain.CreateParams(var Params: TCreateParams);
begin
  inherited CreateParams(Params);
  Params.Style := (WS_CHILD or WS_MAXIMIZE) and not WS_CAPTION and not WS_BORDER;
  Params.WindowClass.cbWndExtra := SizeOf(PtrInt); // ~4/8 bytes for form
end;

constructor TfmMain.CreateParented(AParentWindow: HWND);
begin
  inherited CreateParented(AParentWindow);
  FTotCmdWin  := FindWindow('TTOTAL_CMD', nil);
  FParentWin  := AParentWindow;
  FQuickView  := Windows.GetParent(FParentWin) <> 0;
end;