procedure TDataset2Excel.ExportDetail;
Var
   i, rowindex: integer;
   row : integer;
   FieldType: TFieldType;
   Field: TField;
   Cell: IXLSRange;
   DValue: TDateTime;
   {$ifndef D2009}
   sValue: AnsiString;
   {$endif}
   h,m,s,ms: word;
   CurPos : TBookmark;
   //SheetRowIndex: integer;
   aLineStyle:  LongWord; 
   aLineWeight: LongWord; 

   lFirstRow: integer;
   TopBorderExist: boolean;

  function DelphiDateFormatToExcelDateFormat(Format: string): string;
  var
    i: integer;
  begin
    Result := Format;
    for i := 1 to Length(Format) do
      case Format[i] of
        'n' { Minutes }: Result[i] := 'm';
        'z' { Milisec }: Result[i] := '0';
      end;

    Result := StringReplace(Result, 'ampm', 'AM/PM', [rfReplaceAll,rfIgnoreCase]);
    Result := StringReplace(Result, 'a/p',  'AM/PM', [rfReplaceAll,rfIgnoreCase]);
  end;
  
  function DelphiNumericFormatToExcelNumericFormat(Format: string): string;
  begin
    Result := Format;
    Result := StringReplace(Result, 'S', '\S', [rfReplaceAll]);
    Result := StringReplace(Result, 's', '\s', [rfReplaceAll]);
  end;

begin
  FDataset.DisableControls;
  CurPos := FDataset.GetBookmark;
  FDataset.First;
try
  SetupGroupStorage;
  FWorksheet.Outline.SummaryRow := xlAbove;

  row := 1 + FRowOffset + FRowsPerHeader;
  lFirstRow := row;
  rowindex := 0;
  //SheetRowIndex := 0;

  while not(DataSet.Eof) do begin
     Inc(rowindex);
     Inc(FSheetRowIndex);
     FFieldsExported := 0;

     ProcessGroups(row);

     for i := 1 to FFieldsCount do begin

       if VisibleFieldsOnly and Not(FDataset.Fields[i - 1].Visible) then Continue;

       Inc(FFieldsExported);

       if FClearGroupFields and FGroupStorage.Enabled then begin
          if FGroupStorage.IsGroupField(FDataSet.Fields[i - 1].FieldName) then begin
             Continue;
          end;
       end;
       
       Field := FDataSet.Fields[i - 1]; 
       FieldType := Field.DataType;
       Cell := FWorksheet.Cells.Item[row, FFieldsExported + FColOffset];

       if FieldType = ftString then begin
          {$ifdef D2009}
          Cell.Value := Field.DisplayText;
          {$else} 
          sValue := Field.DisplayText ;
          Cell.Value := StringToWideString(sValue, DetailFont.Charset);
          {$endif} 
       {$IFNDEF D45}
       end else if (FieldType = ftFMTBcd) and (not Field.IsNull) then begin // Jordi
          Cell.Value := Field.AsFloat;
       end else if (FieldType = ftTimeStamp) then begin
          Cell.Value := Field.AsDateTime;
       {$ENDIF}
       end else begin
          Cell.Value := Field.AsVariant;
       end;

       //font
       if not(foFont in DisableFormat) then begin
           SetCellFont(DetailFont, Cell);
       end;

       //borders
       if not(foBorders in DisableFormat) then begin

           TopBorderExist := (Cell.Borders[xlEdgeTop].LineStyle <> xlLineStyleNone);

           if DetailBorderStyle <> BorderStyleNone then begin
              aLineStyle  := xlLineStyleNone;
              aLineWeight := xlThin; 
              case DetailBorderStyle of
                 BorderStyleSingleHair: begin
                                          aLineStyle  := xlContinuous;
                                          aLineWeight := xlHairline; 
                                        end;
                 BorderStyleSingleThick:begin
                                          aLineStyle  := xlContinuous;
                                          aLineWeight := xlThick; 
                                        end;
                 BorderStyleSingleThin:begin
                                          aLineStyle  := xlContinuous;
                                          aLineWeight := xlThin; 
                                        end;
                 BorderStyleDouble:begin
                                          aLineStyle  := xlDouble;
                                          aLineWeight := xlThick; 
                                        end;
              end;

              Cell.Borders[xlEdgeBottom].LineStyle := aLineStyle;
              Cell.Borders[xlEdgeLeft].LineStyle   := aLineStyle;
              Cell.Borders[xlEdgeRight].LineStyle  := aLineStyle;

              if aLineStyle <> xlLineStyleNone then begin
                 Cell.Borders[xlEdgeBottom].Weight := aLineWeight;
                 Cell.Borders[xlEdgeLeft].Weight   := aLineWeight;
                 Cell.Borders[xlEdgeRight].Weight  := aLineWeight;
              end;

              if Not(TopBorderExist) then begin
                  Cell.Borders[xlEdgeTop].LineStyle := aLineStyle;
                  if aLineStyle <> xlLineStyleNone then begin
                      Cell.Borders[xlEdgeTop].Weight := aLineWeight;
                  end;
              end;

           end;

           if DetailBorderColor <> clNone then begin
               Cell.Borders[xlEdgeBottom].Color := ColorToRGB(DetailBorderColor);
               Cell.Borders[xlEdgeLeft].Color   := ColorToRGB(DetailBorderColor);
               Cell.Borders[xlEdgeRight].Color  := ColorToRGB(DetailBorderColor);
               if Not(TopBorderExist) then 
                  Cell.Borders[xlEdgeTop].Color  := ColorToRGB(DetailBorderColor);
           end;

       end;

       //numberformat
       if not(foNumberFormat in DisableFormat) then begin
           
           case FieldType of

              ftDate: if TDateField(Field).DisplayFormat <> '' then begin
                         Cell.NumberFormat := DelphiDateFormatToExcelDateFormat(TDateField(Field).DisplayFormat);
                      end else begin
                         Cell.NumberFormat := DelphiDateFormatToExcelDateFormat({$IFDEF D2011}FormatSettings.{$ENDIF}ShortDateFormat); // 'dd.mm.yyyy';
                      end;

              ftTime: if TTimeField(Field).DisplayFormat <> '' then begin
                         Cell.NumberFormat := DelphiDateFormatToExcelDateFormat(TTimeField(Field).DisplayFormat);
                      end else begin
                         Cell.NumberFormat := DelphiDateFormatToExcelDateFormat({$IFDEF D2011}FormatSettings.{$ENDIF}ShortTimeFormat); // 'hh:mm:ss';
                      end;


              ftDateTime:
                      if TDateTimeField(Field).DisplayFormat <> '' then begin
                         Cell.NumberFormat := DelphiDateFormatToExcelDateFormat(TDateTimeField(Field).DisplayFormat);
                      end else begin
                         //bug modified by Michael Tien Jan 09, 2006
                         DValue := Field.asDateTime;
                         DecodeTime(DValue, h, m, s, ms);
                         if (h + m + s + ms) > 0 then
                            Cell.NumberFormat := DelphiDateFormatToExcelDateFormat({$IFDEF D2011}FormatSettings.{$ENDIF}ShortDateFormat + ' ' + {$IFDEF D2011}FormatSettings.{$ENDIF}ShortTimeFormat) // 'dd.mm.yyyy hh:mm:ss'
                         else
                            Cell.NumberFormat := DelphiDateFormatToExcelDateFormat({$IFDEF D2011}FormatSettings.{$ENDIF}ShortDateFormat); //'dd.mm.yyyy'
                      end;

              ftCurrency:
                      if TCurrencyField(Field).DisplayFormat <> '' then begin
                         Cell.NumberFormat := TCurrencyField(Field).DisplayFormat;
                      end else begin
                         Cell.NumberFormat := '#,##0.00';
                      end;

              ftInteger,
              ftSmallint,
              ftWord,
              ftFloat,
              ftBCD,
              {$IFNDEF D45}
              ftFMTBcd,
              {$ENDIF}
              ftLargeint:
                      if TNumericField(Field).DisplayFormat <> '' then begin
                         Cell.NumberFormat := DelphiNumericFormatToExcelNumericFormat(TNumericField(Field).DisplayFormat);
                      end;

              ftBoolean: {$ifdef D2009}
                         Cell.Value := Field.Text;
                         {$else}
                         Cell.Value := StringToWideString(Field.Text, DetailFont.Charset);
                         {$endif} 
           end;
       end;

       //alignment
       if not (foAlignment in DisableFormat) then begin
          case Field.Alignment of
             taCenter:       Cell.HorizontalAlignment := xlHAlignCenter;
             taLeftJustify:  Cell.HorizontalAlignment := xlHAlignLeft;
             taRightJustify: Cell.HorizontalAlignment := xlHAlignRight;
          end;
       end;

//       if not(foAlignment in DisableFormat) then begin
//           if FieldType in [ftDate, ftTime, ftDateTime] then
//                 Cell.HorizontalAlignment := xlHAlignLeft;
//       end;

       if Assigned(FAfterDetailCell) then FAfterDetailCell(Self, Cell, rowindex, i - 1, Field);
     end;

     if Assigned(FAfterDetailRow) and (FFieldsExported > 0) then
        FAfterDetailRow(Self, FWorksheet.RCRange[ row, FColOffset + 1,
                                                  row, FFieldsExported + FColOffset], rowindex);

     FDataset.Next;
     Inc(row);

     //pagebreak
     if (row > FRowsPerSheet) and not(FDataSet.Eof) then begin
        //FAfterDetail
       if Assigned(FAfterDetail) and 
          (FFieldsExported > 0)     and 
          ((row - 1) > (FRowsPerHeader + FRowOffset)) then
          FAfterDetail(Self, FWorksheet.RCRange[FRowsPerHeader + FRowOffset + 1,
                                                FColOffset + 1,
                                                row - 1, 
                                                FFieldsExported + FColOffset]);
       if Assigned(FAfterExport) and
          (FFieldsExported > 0)     and 
          ((row - 1 - FRowOffset) > 0) then
          FAfterExport(Self, FWorksheet.RCRange[ FRowOffset + 1,
                                                 FColOffset + 1,
                                                 row - 1, 
                                                 FFieldsExported + FColOffset]);


        CreateWorksheet;
        ExportHeaders;
        row := FRowsPerHeader + 1 + FRowOffset;
        lFirstRow := row;
        CloseGroups();
        //SheetRowIndex := 0;
     end;

   end;
//   FRowsCount := SheetRowIndex;
   FRowsCount := row - lFirstRow;

   if Assigned(FAfterDetail) and
      (FFieldsExported > 0)     and 
      ((row - 1) > (FRowsPerHeader + FRowOffset)) then
      FAfterDetail(Self, FWorksheet.RCRange[FRowsPerHeader + FRowOffset + 1,
                                            FColOffset + 1,
                                            row - 1, 
                                            FFieldsExported + FColOffset]);
finally                                         
   FDataset.GotoBookmark(CurPos);
   FDataset.EnableControls;
   FDataset.FreeBookmark(CurPos);
end;

end;