var
  Services: INTAServices;
  ItemBmp: TBitmap;
  BkColor: TColor;
  ID: String;
  
  ItemIndex: Integer;
  Item: TImageCollectionItem;
  Source: TImageCollectionSourceItem;
  Icon: TIcon;
  Stream: TMemoryStream;
 
// ...
 
MenuItem.ImageIndex := Services.AddMasked(ItemBmp, BkColor, ID);
 
if (MenuItem.ImageIndex >= 0) and
   (Services.ImageList is TVirtualImageList) and
   (TVirtualImageList(Services.ImageList).ImageCollection is TImageCollection) then
begin
  ItemIndex := TVirtualImageList(Services.ImageList).Images[MenuItem.ImageIndex].CollectionIndex;
  Item := TImageCollection(TVirtualImageList(Services.ImageList).ImageCollection).Images[ItemIndex];
 
  if Item.SourceImages.Count = 1 then
    Source := Item.SourceImages[0]
  else
  begin
    Item.SourceImages.Clear;
    Source := Item.SourceImages.Add;
  end;
 
  Icon := ConvertBitmapToIcon(ItemBmp, BkColor);
  try
    Stream := TMemoryStream.Create;
    try
      Icon.SaveToStream(Stream);
      Stream.Position := 0;
      Source.Image.LoadFromStream(Stream);
    finally
      FreeAndNil(Stream);
    end;
  finally
    FreeAndNil(Icon);
  end;
 
  TVirtualImageList(Services.ImageList).UpdateImageList;
end;

function ConvertBitmapToIcon(const ABitmap: TBitmap; const ATransparentColor: TColor): TIcon;
var
  II: TIconInfo;
  Mask: TBitmap;
  X, Y: Integer;
begin
  Result := TIcon.Create;
  try
    Mask := TBitmap.Create(ABitmap.Width, ABitmap.Height);
    try
      Mask.Canvas.Brush.Color := clBlack;
      Mask.Canvas.FillRect(Rect(0, 0, Mask.Width, Mask.Height));
      for Y := 0 to Mask.Height - 1 do
        for X := 0 to Mask.Width - 1 do
          if ABitmap.Canvas.Pixels[X, Y] = ATransparentColor then
            Mask.Canvas.Pixels[X, Y] := clWhite;
 
      FillChar(II, SizeOf(II), 0);
      II.fIcon := True;
      II.hbmMask := Mask.Handle;
      II.hbmColor := ABitmap.Handle;
      Result.Handle := CreateIconIndirect(II);
    finally
      FreeAndNil(Mask);
    end;
  except
    FreeAndNil(Result);
    raise;
  end;
end;