procedure TfmMain.SetBar;
Var dSize: integer;
begin
  ZeroMemory(@AppBarData, SizeOf(TAppBarData));
  AppBarData.cbSize:=SizeOf(TAppBarData);
  // Добавляем наше окошко в список панелей задач Windows
  AppBarData.hWnd:=Handle;
  AppBarData.uCallbackMessage:=WM_APP+$101;
  Case mPosition of
    mLeft:   AppBarData.uEdge := ABE_LEFT;
    mTop:    AppBarData.uEdge := ABE_TOP;
    mRight:  AppBarData.uEdge := ABE_RIGHT;
    mBottom: AppBarData.uEdge := ABE_BOTTOM;
  end;
  AppBarData.lParam := 1;

  SHAppBarMessage(ABM_NEW, AppBarData);
  // Запрашиваем размеры свободной области экрана (ну то что пока не занято другими панелями задач)   
  AppBarData.rc:=Rect(0, 0, GetSystemMetrics(SM_CXSCREEN), GetSystemMetrics(SM_CYSCREEN));
  SHAppBarMessage(ABM_QUERYPOS, AppBarData);
  //  Уточняем ширину нашей панельки (ну это чисто наш код, можно просто написать 50)
  if mHide
    then dSize := cNotFloatDepth
    else dSize := mDepth;

  // Переопределяем размеры области для нашей панельки в зависимости от того
  //   к какой стороне экрана лепим нашу панельку  
  case mPosition of
    mLeft:   AppBarData.rc.Right  := AppBarData.rc.Left + dSize;
    mTop:    AppBarData.rc.Bottom := AppBarData.rc.Top + dSize;
    mRight:  AppBarData.rc.Left := AppBarData.rc.Right - dSize;
    mBottom: AppBarData.rc.Top := AppBarData.rc.Bottom - dSize;
  end;
  // Блокируем эту область под себя
  SHAppBarMessage(ABM_SETPOS, AppBarData);
  // Передвигаем нашу формочку на наше законное место
  SetWindowPos(Handle,
               Handle,
               AppBarData.rc.left,
               AppBarData.rc.top,
               AppBarData.rc.right-AppBarData.rc.left,
               AppBarData.rc.bottom-AppBarData.rc.top,
               SWP_NOZORDER or SWP_NOACTIVATE);

  SetBounds(AppBarData.rc.left
           ,AppBarData.rc.top
           ,AppBarData.rc.Right-AppBarData.rc.Left
           ,AppBarData.rc.Bottom-AppBarData.rc.Top);
end;