procedure TformDEOperations.tvMainPARAMS_MASKCustomDrawCell(
  Sender: TcxCustomGridTableView; ACanvas: TcxCanvas;
  AViewInfo: TcxGridTableDataCellViewInfo; var ADone: Boolean);

  procedure DrawRhomb(ACanvas: TCanvas; const x, y: Integer; const AColor: TColor; const ASize: Integer = 5);
  begin
    with ACanvas do
    begin
      Brush.Style := bsSolid;
      Brush.Color := AColor;
      Pen.Color   := AColor;
      Polygon([
        Point(x, y),
        Point(x + ASize, y - ASize),
        Point(x + 2 * ASize, y),
        Point(x + ASize, y + ASize)
      ]);
    end;
  end;

const
  RhombSize = 4;
var
  ARect: TRect;
  x, y: Integer;
  AMask: Int64;
begin
  if not Assigned(AViewInfo) then
    Exit;
  AMask := StrToInt64Def(VarToStr(AViewInfo.GridRecord.Values[tvMainPARAMS_MASK.Index]), 0);
  ARect := AViewInfo.Bounds;
  ACanvas.FillRect(ARect, AViewInfo.Params.Color);
  x     := ARect.Left + 2;
  y     := ARect.Top  - 1 + (ARect.Bottom - ARect.Top) div 2;
  // Draw Rhombs
  // Обработанный или необработанный пакет
  if AMask and 8 = 8 then // В процессе обработки обнаружены ошибки
    DrawRhomb(ACanvas.Canvas, x, y, clOlive, RhombSize)
  else if AMask and 1 = 1 then
    DrawRhomb(ACanvas.Canvas, x, y, clLime, RhombSize)
  else
    DrawRhomb(ACanvas.Canvas, x, y, clRed, RhombSize);
  Inc(x, 2 * RhombSize + 3);
  // Выгруженный пакет
  if AMask and 2 = 2 then
    DrawRhomb(ACanvas.Canvas, x, y, clFuchsia, RhombSize);
  Inc(x, 2 * RhombSize + 3);
  // В пакете есть PB2
  if AMask and 4 = 4 then
    DrawRhomb(ACanvas.Canvas, x, y, clBlack, RhombSize);
  ADone := True;
end;