function GetFilesList(ADirName: string; AFileMask: string; ASearchSubdirs: Boolean): TStringList;
var
  list: TStringList;
  I: Integer;
  normalDir: string;
  options: TSearchOption;
  filesList: TStringDynArray;
begin
  // получает список файлов в папке и всех подпапках по маске вида *.*
  // автор: jaydi85@gmail.com

  if ADirName = '' then
  begin
    raise Exception.Create('ERROR! ADirName must be non empty.');
  end;

  list := TStringList.Create;
  Result := list;

  // доп проверка, т.к. если папки нет, то TDirectory.GetFiles вызывет исключение
  if not DirectoryExists(ADirName) then
  begin
    Exit;
  end;

  if not EndsText('\', ADirName) then
  begin
    normalDir := ADirName + '\';
  end
  else
  begin
    normalDir := ADirName;
  end;

  // новая версия поиска через IOUtils
  if ASearchSubdirs then
  begin
    options := TSearchOption.soAllDirectories;
  end
  else
  begin
    options := TSearchOption.soTopDirectoryOnly;
  end;

  filesList := TDirectory.GetFiles(normalDir, AFileMask, options);

  for I := 0 to Length(filesList) - 1 do
  begin
    list.Add(filesList[I]);
  end;
end;