{
**************************** !!! ВНИМАНИЕ !!! *****************************
  Для корректной работы с драйвером в режиме отладки необходимо в среде
разработки отключить остановку на исключительных ситуациях.
  Эта опция находится в меню "Tools\Debugger Options", закладка
"Language Exceptions". Флаг "Stop On Delphi Exceptions" необходимо снять.
***************************************************************************
}
unit fmuMain;

interface

uses
  Windows, Messages, SysUtils, Classes, Graphics, Controls, Forms, Dialogs,
  StdCtrls, ComObj;

type
  TfrmMain = class(TForm)
    btnStart: TButton;
    btnShowProperties: TButton;
    procedure btnShowPropertiesClick(Sender: TObject);
    procedure btnStartClick(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
    procedure FormShow(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

var
  frmMain: TfrmMain;
  ECR: OleVariant;

implementation

{$R *.DFM}

procedure Demo;
begin
// занимаем порт
  ECR.DeviceEnabled := true;
  if ECR.ResultCode <> 0 then Exit;

// получаем состояние ККМ
  if ECR.GetStatus <> 0 then Exit;

// проверяем на всякий случай ККМ на фискализированность
  if ECR.Fiscal then
    if Application.MessageBox('ККМ фискализирована! Вы действительно хотите продолжить?', PChar(Application.Title), MB_ICONEXCLAMATION + MB_YESNO) = idNo then
      Exit;

// если есть открытый чек, то отменяем его
  if ECR.CheckState <> 0 then
    if ECR.CancelCheck <> 0 then Exit;

// если смена открыта снимаем Z-отчет
  if ECR.SessionOpened then
  begin
    // устанавливаем пароль системного администратора ККМ
    ECR.Password := '30';
    // входим в режим отчетов с гашением
    ECR.Mode := 3;
    if ECR.SetMode <> 0 then Exit;
    // снимаем отчет
    ECR.ReportType := 1;
    if ECR.Report <> 0 then Exit;
  end;

// входим в режим регистрации
  // устанавливаем пароль кассира
  ECR.Password := '1';
  // входим в режим регистрации
  ECR.Mode := 1;
  if ECR.SetMode <> 0 then Exit;

// продажа без сдачи
  // регистрация продажи
  ECR.Name := 'Молоко';
  ECR.Price := 10.45;
  ECR.Quantity := 1;
  ECR.Department := 2;
  if ECR.Registration <> 0 then Exit;
  // скидка суммой на предыдущую позицию
  ECR.Percents := 10;
  ECR.Destination := 1;
  if ECR.PercentsDiscount <> 0 then Exit;
  // регистрация продажи
  ECR.Name := 'Фанта';
  ECR.Price := 25;
  ECR.Quantity := 5;
  ECR.Department := 1;
  if ECR.Registration <> 0 then Exit;
  // скидка суммой на весь чек
  ECR.Summ := 10.40;
  ECR.Destination := 0;
  if ECR.SummDiscount <> 0 then Exit;
  // закрытие чека наличными без ввода полученной от клиента суммы
  ECR.TypeClose := 0;
  if ECR.CloseCheck <> 0 then Exit;

// продажа со сдачей
  // регистрация продажи
  ECR.Name := 'Молоко';
  ECR.Price := 10.45;
  ECR.Quantity := 1;
  ECR.Department := 2;
  if ECR.Registration <> 0 then Exit;
  // регистрация продажи
  ECR.Name := 'Пепси-кола';
  ECR.Price := 25.00;
  ECR.Quantity := 5;
  ECR.Department := 1;
  if ECR.Registration <> 0 then Exit;
  // сторно предыдущей регистрации
  if ECR.Storno <> 0 then Exit;
  // регистрация продажи
  ECR.Name := 'Фанта';
  ECR.Price := 25;
  ECR.Quantity := 5;
  ECR.Department := 1;
  if ECR.Registration <> 0 then Exit;
  // скидка суммой на весь чек
  ECR.Summ := 50;
  ECR.Destination := 0;
  if ECR.SummDiscount <> 0 then Exit;
  // закрытие чека наличными с вводом полученной от клиента суммы
  ECR.Summ := 100;
  ECR.TypeClose := 0;
  if ECR.Delivery <> 0 then Exit;

// аннулирование
  // регистрация аннулирования
  ECR.Name := 'Dirol';
  ECR.Price := 7;
  ECR.Quantity := 1;
  if ECR.Annulate <> 0 then Exit;
  // регистрация аннулирования
  ECR.Name := 'Orbit';
  ECR.Price := 8;
  ECR.Quantity := 2;
  if ECR.Annulate <> 0 then Exit;
  // закрытие чека
  ECR.TypeClose := 0;
  if ECR.CloseCheck <> 0 then Exit;

// возврат
  // регистрация возврата
  ECR.Name := 'Молоко';
  ECR.Price := 10.45;
  ECR.Quantity := 1;
  if ECR.Return <> 0 then Exit;
  // регистрация возврата
  ECR.Name := 'Колбаса';
  ECR.Price := 99.99;
  ECR.Quantity := 1.235;
  if ECR.Return <> 0 then Exit;
  // скидка суммой на весь чек
  ECR.Summ := 50;
  ECR.Destination := 0;
  if ECR.SummDiscount <> 0 then Exit;
  // закрытие чека
  ECR.TypeClose := 0;
  if ECR.CloseCheck <> 0 then Exit;

// внесение наличности
  ECR.Summ := 400.50;
  if ECR.CashIncome <> 0 then Exit;

// выплата наличности
  ECR.Summ := 121.34;
  if ECR.CashOutcome <> 0 then Exit;

// X - отчет
  // устанавливаем пароль администратора ККМ
  ECR.Password := '29';
  // входим в режим отчетов без гашения
  ECR.Mode := 2;
  if ECR.SetMode <> 0 then Exit;
  // снимаем отчет
  ECR.ReportType := 2;
  if ECR.Report <> 0 then Exit;

// Z - отчет
  // устанавливаем пароль системного администратора ККМ
  ECR.Password := '30';
  // входим в режим отчетов с гашением
  ECR.Mode := 3;
  if ECR.SetMode <> 0 then Exit;
  // снимаем отчет
  ECR.ReportType := 1;
  if ECR.Report <> 0 then Exit;

// выходим в режим выбора, чтобы кто-то под введенными паролями не сделал что нибуть нехорошее
  if ECR.ResetMode <> 0 then Exit;

// освобождаем порт
  ECR.DeviceEnabled := false;
  if ECR.ResultCode <> 0 then Exit;

  Application.MessageBox('Все операции успешно выполнены.', PChar(Application.title), MB_ICONINFORMATION + MB_OK);
end;

procedure TfrmMain.btnStartClick(Sender: TObject);
begin
  btnStart.Enabled := false;
  btnShowProperties.Enabled := false;

  Demo;
  if ECR.ResultCode <> 0 then
    Application.MessageBox(PChar('Ошибка ККМ: ' + string(ECR.ResultDescription) + '!'), PChar(Application.Title), MB_ICONERROR + MB_OK);

  btnStart.Enabled := true;
  btnShowProperties.Enabled := true;
end;

procedure TfrmMain.btnShowPropertiesClick(Sender: TObject);
begin
// показываем страницу свойств
  ECR.ShowProperties;
end;

procedure TfrmMain.FormShow(Sender: TObject);
begin
// создаем объект общего драйвера ККМ
// если объект создать не удается генерируется исключение, по которому завершается работа приложения
  try
    ECR := CreateOleObject('AddIn.FprnM45');
    ECR.ApplicationHandle := Application.Handle; // необходимо для корректного отображения окон драйвера в контексте приложения
  except
    Application.MessageBox('Не удалось создать объект общего драйвера ККМ!', PChar(Application.Title), MB_ICONERROR + MB_OK);
    Application.Terminate;
  end;
end;

procedure TfrmMain.FormClose(Sender: TObject; var Action: TCloseAction);
begin
// разрушаем объект драйвера
  ECR := 0;
end;

end.