function GetRealLinkFile(const AFileFullName: string): string;
var
  source: string;
  link: IShellLinkW;
  linkFile: IPersistFile;
  shortPath: array[0..MAX_PATH] of Char;
  findData: TWin32FindData;
  isNeedUninitialize: Boolean;

  function GetLongName(const AFile: string): string;
  var
    longPath: string;
    sz: Integer;
  begin
    // делает из короткого имени длинное
    // см. реализацию в IOUtils.TPath.GetTempPath
    if AFile.Contains('~') then
    begin
      sz := GetLongPathName(PChar(AFile), nil, 0);
      SetLength(longPath, sz - 1);
      GetLongPathName(PChar(AFile), PChar(longPath), sz);
      Result := longPath;
    end
    else
    begin
      Result := AFile;
    end;
  end;

  function CustomFileExists(const AFile: string): Boolean;
  begin
    if AFile.StartsWith('\\') then
    begin
      Result := TFile.Exists(source);
    end
    else
    begin
      Result := TFile.Exists('\\?\' + source);
    end;
  end;

begin
  // получает реальный путь к файлу с учетом ярлыка и преобразует короткое имя с ~ в полное
  // только для windows
  // автор jaydi85@gmail.com
  // на основе https://forums.embarcadero.com/thread.jspa?threadID=171700
  // и https://stackoverflow.com/questions/16874118/delphi-how-to-check-if-a-file-exists-path-over-255-characters
  source := GetLongName(AFileFullName);
  Result := source;

  if (AnsiLowerCase(ExtractFileExt(source)) <> '.lnk') or not CustomFileExists(source) then
  begin
    Exit;
  end;

  // инициализация COM, если код будет вызван из не основного потока или библиотеки
  isNeedUninitialize := SUCCEEDED(CoInitializeEx(nil, COINIT_APARTMENTTHREADED or COINIT_DISABLE_OLE1DDE));
  try
    // ярлык грузится в ShellLink и оттуда вытаскивается адрес
    OleCheck(CoCreateInstance(CLSID_ShellLink, nil, CLSCTX_INPROC_SERVER, IShellLinkW, link));
    try
      OleCheck(link.QueryInterface(IPersistFile, linkFile));
      try
        OleCheck(linkFile.Load(PWideChar(source), STGM_READ));
        OleCheck(link.Resolve(0, SLR_ANY_MATCH or SLR_NO_UI));
        OleCheck(link.GetPath(shortPath, MAX_PATH, findData, SLGP_SHORTPATH));

        Result := GetLongName(shortPath);
      finally
        linkFile := nil;
      end;
    finally
      link := nil;
    end;
  finally
    if isNeedUninitialize then
    begin
      CoUninitialize;
    end;
  end;
end;