unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, SyncObjs, ComCtrls, CommCtrl;

type
  TTestThread = class( TThread )
  private
    FProgressBarHandle: HWND;
    FMax: Integer;
    FWaitEvent: TSimpleEvent;
  protected
    procedure Execute; override;
  public
    constructor Create( AProgressBarHandle: HWND; AMax: Integer );
    destructor Destroy; override;
  end;

  TForm1 = class(TForm)
    btnStart: TButton;
    ProgressBar1: TProgressBar;
    procedure btnStartClick(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    FThread: TTestThread;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

constructor TTestThread.Create( AProgressBarHandle: HWND; AMax: Integer );
begin
  FProgressBarHandle := AProgressBarHandle;
  FMax := AMax;
  FWaitEvent := TSimpleEvent.Create;
  inherited Create( False );
end;

destructor TTestThread.Destroy;
begin
  Terminate;
  FWaitEvent.SetEvent;
  inherited;
  FWaitEvent.Free;
end;

procedure TTestThread.Execute;
var
  i: Integer;
begin
  SendMessage( FProgressBarHandle, PBM_SETRANGE, 0, MakeLong( 0, FMax ) );
  for i := 0 to FMax do begin
    SendMessage( FProgressBarHandle, PBM_SETPOS, i, 0 );
    FWaitEvent.WaitFor( 100 );
    if Terminated then
      Exit;
  end;
end;

procedure TForm1.btnStartClick(Sender: TObject);
begin
  FThread.Free;
  FThread := TTestThread.Create( ProgressBar1.Handle, 1000 );
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  FreeAndNil( FThread );
end;

end.

unit Unit1;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, SyncObjs, ComCtrls;

const
  WM_SET_PROGRESS_STEP = WM_USER + 1;

type
  TTestThread = class( TThread )
  private
    FFormHandle: HWND;
    FMax: Integer;
    FWaitEvent: TSimpleEvent;
  protected
    procedure Execute; override;
  public
    constructor Create( AFormHandle: HWND; AMax: Integer );
    destructor Destroy; override;
  end;

  TForm1 = class(TForm)
    btnStart: TButton;
    ProgressBar1: TProgressBar;
    procedure btnStartClick(Sender: TObject);
    procedure FormClose(Sender: TObject; var Action: TCloseAction);
  private
    FThread: TTestThread;
    procedure OnNeedStep( var Msg: TMessage ); message WM_SET_PROGRESS_STEP;
  end;

var
  Form1: TForm1;

implementation

{$R *.dfm}

constructor TTestThread.Create( AFormHandle: HWND; AMax: Integer );
begin
  FFormHandle := AFormHandle;
  FMax := AMax;
  FWaitEvent := TSimpleEvent.Create;
  inherited Create( False );
end;

destructor TTestThread.Destroy;
begin
  Terminate;
  FWaitEvent.SetEvent;
  inherited;
  FWaitEvent.Free;
end;

procedure TTestThread.Execute;
var
  i: Integer;
begin
  for i := 0 to FMax do begin
    SendMessage( FFormHandle, WM_SET_PROGRESS_STEP, i, 0 );
    FWaitEvent.WaitFor( 100 );
    if Terminated then
      Exit;
  end;
end;

procedure TForm1.btnStartClick(Sender: TObject);
begin
  FThread.Free;
  ProgressBar1.Max := 1000;
  FThread := TTestThread.Create( Handle, ProgressBar1.Max );
end;

procedure TForm1.OnNeedStep( var Msg: TMessage );
begin
  ProgressBar1.Position := Msg.WParam;
end;

procedure TForm1.FormClose(Sender: TObject; var Action: TCloseAction);
begin
  FreeAndNil( FThread );
end;

end.