procedure TMemTable.LoadFromDataSet(DataSet: TDataSet);
var
  i     : Integer;
  Field : TField;
begin
  Tag := 1;
  DataSet.Open;
  DataSet.First;
  try
    inherited Close;
    DisableControls;
    FieldDefs.Clear;
    for i := 0 to DataSet.FieldCount -1 do begin
      Field := DataSet.Fields[i];
      FieldDefs.Add(Field.FieldName, Field.DataType, Field.Size, FALSE);
    end; // for i := 0 to DataSet.FieldCount
    inherited Open;
    while not DataSet.Eof do begin
      inherited Append;
      for i := 0 to DataSet.FieldCount - 1 do  begin
        Field := DataSet.Fields[i];
        if not VarIsNull(Field.Value) then begin
          case Field.DataType of
            ftTime,
            ftDate,
            ftDateTime : Fields[i].AsDateTime := Field.AsDateTime;
            ftOraBlob,
            ftBlob     : Fields[i].Value      := Field.Value;
            ftMemo     : Fields[i].AsString   := Field.AsString;
            ftBoolean  : Fields[i].AsBoolean  := Field.AsBoolean;
            ftSmallInt ,
            ftInteger  ,
            ftWord     ,
            ftAutoInc  : Fields[i].AsInteger  := Field.AsInteger;
            ftFloat    : Fields[i].AsFloat    := Field.AsFloat;
            ftBCD,
            ftCurrency : Fields[i].AsCurrency := Field.AsCurrency;
            ftString   : Fields[i].AsString   := Field.AsString;
            else         Fields[i].Value      := Field.Value;
          end; // case Field.DataType
        end; // if not VarIsNull(Field.Value)
      end; // for i := 0 to DataSet.FieldCount
      inherited Post;
      DataSet.Next;
    end; // while not DataSet.Eof
    First;
  finally
    EnableControls;
    Tag := 0;
  end;
end;