char table[256] = { ... };
    uint32_t popcount2(uint32_t i)
    {
        union{
            uint32_t i;
            char c[4];
        }x;

        x.i = i;

        uint32_t res;

        res = table[ x.c[0] ];
        res += table[ x.c[1] ];
        res += table[ x.c[2] ];
        res += table[ x.c[3] ];

        return res;
    }

	; fasm 1.71.39

	format PE console
	include 'win32axp.inc'

	.data

	format_string  db 'key(HEX) = %04X%04X',9,'%d.%d sek',0
	output_string  db 256 dup ( 0 )

	SystemTimeBegin SYSTEMTIME
	SystemTimeEnd	SYSTEMTIME
	FileTimeBegin	dd 0, 0
	FileTimeEnd	dd 0, 0

	key dd 0, 0

	.code
start:

	; Для расчета быстродействия запрашиваем системное время начала цикла
	invoke GetSystemTime, SystemTimeBegin

	; расчет ключа 64 бита
	;   начальное значение 1
	;   вычислить значение ключа через 2000000000 минут
	mov edi, 2000000000
	xor ecx, ecx
	mov ebx, 1
 @@:
	; key = key + popcount(key)
	; ebx - младшие 32 бита key
	; eсx - старшие 32 бита key

	; popcount 64 бита
	popcnt eax, ebx
	popcnt edx, ecx
	add eax, edx

	; key + popcount(key)
	add ebx, eax
	adc ecx, 0

	dec edi
	jnz @b
	mov [key], ebx
	mov [key + 4], ecx

	; Для расчета быстродействия запрашиваем системное время окончания цикла
	invoke GetSystemTime, SystemTimeEnd

	; для удобства расчета переводим SYSTEMTIME в FILETIME
	invoke SystemTimeToFileTime, SystemTimeBegin, FileTimeBegin
	invoke SystemTimeToFileTime, SystemTimeEnd, FileTimeEnd
	; TimeEnd - TimeBegin
	; eax - секунды
	; edx - миллисек
	mov eax, [FileTimeEnd]
	mov edx, [FileTimeEnd + 4]
	sub eax, [FileTimeBegin]
	sbb edx, [FileTimeBegin + 4]
	mov ebx, 10000000
	div ebx

	cinvoke wsprintfA, output_string, format_string, [key + 4], [key], eax, edx
	invoke MessageBoxA, 0, output_string, 'Test', MB_OK

	invoke ExitProcess,0
	.end start