(******************************************************************************)
(*  dfmcnv.dpr                                                                *)
(*    DFM conversion utility                                                  *)
(*    Author:   Nikolai Adrianov                                              *)
(*                                                                            *)
(*  v1. 00    04 / 05 / 2004                                                          *)
(*    Initial version                                                         *)
(*                                                                            *)
(******************************************************************************)
program dfmcnv;

{$APPTYPE CONSOLE}

uses
  SysUtils;

type
  TConvertorState = (csNormal, csBehindSharp, csInsideQuotes);

procedure ConvertLine(var LineIn, LineOut: String);
var
  Ch: Char;
  Hex: String;
  State: TConvertorState;
  i: Integer;
begin
  State := csNormal;
  Hex := '';
  LineOut := '';
  i :=  1 ;
  while i <= Length(LineIn) +  1  do begin
    Ch := LineIn[i];
    case (State) of
    csNormal:
      if Ch = '#' then begin
        State := csBehindSharp;
        LineOut := LineOut + '''';
        Inc(i);
      end else if Ch = '''' then begin
        State := csInsideQuotes;
        LineOut := LineOut + Ch;
        Inc(i);
      end else begin
        LineOut := LineOut + Ch;
        Inc(i);
      end;
    csInsideQuotes:
      if Ch = '''' then begin
        if LineIn[i +  1 ] = '''' then begin
          LineOut := LineOut + Ch + Ch;
          Inc(i,  2 );
        end else if LineIn[i +  1 ] = '#' then begin
          State := csBehindSharp;
          Inc(i,  2 );
        end else begin
          State := csNormal;
          LineOut := LineOut + Ch;
          Inc(i);
        end;
      end else begin
        LineOut := LineOut + Ch;
        Inc(i);
      end;
    csBehindSharp:
      if Ch in ['0'..'9'] then begin
        Hex := Hex + Ch;
        Inc(i);
      end else begin
        LineOut := LineOut + String(WideChar(StrToInt(Hex)));
        Hex := '';
        if Ch = '''' then begin
          State := csInsideQuotes;
          Inc(i);
        end else if Ch = '#' then begin
          State := csBehindSharp;
          Inc(i);
        end else begin
          State := csNormal;
          LineOut := LineOut + '''' + Ch;
          Inc(i);
        end;
      end;
    end;
  end;
  SetLength(LineOut, Length(LineOut) -  1 );
end;

procedure ConvertFile(FileNameIn, FileNameOut: String);
var
  FileIn, FileOut: TextFile;
  LineIn, LineOut: String;
begin
  AssignFile(FileIn, FileNameIn);
  Reset(FileIn);
  try
    AssignFile(FileOut, FileNameOut);
    Rewrite(FileOut);
    try
      while not EOF(FileIn) do begin
        Readln(FileIn, LineIn);
        ConvertLine(LineIn, LineOut);
        Writeln(FileOut, LineOut);
      end;
    finally
      CloseFile(FileOut);
    end;
  finally
    CloseFile(FileIn);
  end;
end;

procedure ProcessFile(FileName: String);
begin
  Writeln('Processing file: ' + FileName);
  ConvertFile(FileName, FileName + '.d5');
  DeleteFile(FileName);
  RenameFile(FileName + '.d5', FileName);
end;

procedure ProcessDir(DirName: String);
var
  sr: TSearchRec;
begin
  Writeln('Processing directory: ' + DirName);
  if FindFirst(DirName + '\*.dfm', $7FFFFFFF, sr) =  0  then begin
    try
      repeat
        ProcessFile(DirName + '\' + sr.Name);
      until FindNext(sr) <>  0 ;
    finally
      FindClose(sr);
    end;
  end;
end;

procedure Usage;
begin
  Writeln('Usage: dfmcnv.exe [-f<filename>|-d<dirname>|-c|-?]');
  Writeln('  f - converts specified DFM file');
  Writeln('  d - converts all DFM''s in the directory');
  Writeln('  c - converts all DFM''s in the *current* directory');
  Writeln('  ? - displays this help.');
end;

var
  i: Integer;
  Flag: Char;
  Param, FileName, DirName: String;
begin
  Writeln('DFM conversion utility. (c) Nikolai Adrianov, 2004');
  try
    for i :=  1  to ParamCount do begin
      Param := ParamStr(i);
      if (Length(Param) <  2 ) or
        ((Param[ 1 ] <> '-') and (Param[ 1 ] <> '/')) then
      begin
        Writeln(Format('Incorrect parameter #%d: %s'# 13 # 10 , [i, Param]));
        Usage;
        ExitCode := - 1 ;
        Exit;
      end;
      Flag := Param[ 2 ];
      Delete(Param,  1 ,  2 );
      case Flag of
      'f':
        FileName := ExpandFileName(Param);
      'd':
        DirName := ExpandFileName(Param);
      'c':
        DirName := GetCurrentDir;
      '?', 'h':
        begin
          Usage;
          ExitCode :=  0 ;
          Exit;
        end;
      end;
    end;
    if FileName <> '' then begin
      ProcessFile(FileName);
    end else if DirName <> '' then begin
      ProcessDir(DirName);
    end else begin
      Writeln('No file or directory name specified.'# 13 # 10 );
      Usage;
      ExitCode := - 1 ;
      Exit;
    end;
  except on E: Exception do
    Writeln(E.Message);
  end;
end.