Private Sub Form_Load()
  MakeMailSlot("\\.\mailslot\MailSlots")
End Sub

Private Sub CommandReadAll_Click()
  Dim the_Message As String
  Dim the_MsgCount As Long
  Do
    If MailSlotReadFirst(the_Message, the_MsgCount) Then
      '---обработка сообщения---
      MsgBox the_Message
      '---обработка сообщения---
      If the_MsgCount = 0 Then Exit Do
    Else
      Exit Do
    End If
  Loop
End Sub

Private Sub Form_Unload(Cancel As Integer)
  CloseMailSlot 'правда смысла нет, он ПО-ЛЮБОМУ уничтожится ВМЕСТЕ С ПРОЦЕССОМ
End Sub

'==========
Public hMailSlotHandle As Long

Public Function MakeMailSlot(ByVal lpszSlotName As String) As Boolean
  'ПРИЕМНИК(сервер) ф-ция создает MailSlot с именем lpszSlotName
  'невозможно создать более одного MailSlot с заданным именем
  Dim m_tSA As SECURITY_ATTRIBUTES

  If LenB(lpszSlotName) = 0 Then
    ' No slotname
    hMailSlotHandle = INVALID_HANDLE_VALUE
    MakeMailSlot = False
    Exit Function
  End If
 
  ' The handle to the slot
  hMailSlotHandle = CreateMailslot(lpszSlotName, 0, 0, m_tSA)
  
  MakeMailSlot = (hMailSlotHandle > 0)
End Function

Public Sub CloseMailSlot()
  'ПРИЕМНИК(сервер) ф-ция уничтожает MailSlot
  'При этом все непрочитанные сообщения также уничтожаются
  'При закрытии приложения (включая принудительное типа End Task/kill) MailSlot и сообщения также уничтожатся
  If hMailSlotHandle > 0 Then
    CloseHandle hMailSlotHandle
    hMailSlotHandle = INVALID_HANDLE_VALUE
  End If
End Sub

Public Function AvailableMessages() As Long
  'ПРИЕМНИК(сервер) ф-ция возвращает общее к-во сообщений, доступных для чтения
  If hMailSlotHandle = INVALID_HANDLE_VALUE Then Exit Function
  GetMailslotInfo hMailSlotHandle, 0, 0, AvailableMessages, 0
End Function

Public Function MailSlotReadFirst(ByRef m_Message As String, ByRef m_MsgCount As Long) As Boolean
  'ПРИЕМНИК(сервер) ф-ция читает первое сообщение если есть
  'возвращает True, если есть хотя бы одно и оно было прочитано
  'm_Message (Out)-текст сообщения, если прочли
  'm_MsgCount -к-во сообщений оставшихся после чтения (без учета прочитанного)
  Dim lBufferSize As Long
  m_Message = ""
  m_MsgCount = 0
  GetMailslotInfo hMailSlotHandle, 0, lBufferSize, m_MsgCount, 0
  If m_MsgCount > 0 Then
    Dim sBuffer As String, lBytesRead As Long
    ' Create a buffer
    sBuffer = String(lBufferSize, 0)
    
    ' Read data: optional параметры ф-ции не используем
    If ReadFile(hMailSlotHandle, sBuffer, lBufferSize) Then
      m_Message = sBuffer
      m_MsgCount = m_MsgCount - 1
      MailSlotReadFirst = True
    End If
  End If
End Function

Private Sub CommandSend_Click()
  SendMessageToMailSlot Text1.Text, "\\.\mailslot\MailSlots"
End Sub
'====

Public Function SendMessageToMailSlot(ByVal sMessage As String, ByVal sMailSlot As String) As Boolean
  'ПЕРЕДАТЧИК(клиент)ф-ция отправляет сообщение sMessage серверу с именем sMailSlot
  'если сервер не запущен, то сообщение не отправляется
  Dim hFile As Long
  Dim m_tSA As SECURITY_ATTRIBUTES
  
  hFile = CreateFile(sMailSlot, _
                     GENERIC_WRITE, _
                     FILE_SHARE_READ, _
                     m_tSA, _
                     OPEN_EXISTING, _
                     FILE_ATTRIBUTE_NORMAL)
  If hFile = INVALID_HANDLE_VALUE Then Exit Function
  
  SendMessageToMailSlot = WriteFile(hFile, sMessage, Len(sMessage))
  CloseHandle hFile
End Function