Разработка Excel отчетов

	Отчет Excel – вид отчета, формируемый при помощи приложения Microsoft Excel. Система поддерживает создание, редактирование и запуск шаблона Excel.

	Для правильного взаимодействия с системой ИС-ПРО при разработке шаблона следует придерживаться определенных правил:
 - на внешний вид и содержимое шаблона не накладывается никаких ограничений
 - VBA программы формирования отчета должны начинать работу внутри подпрограммы ReportMain
 - подпрограмма ReportMain служит «точкой входа» в программный блок отчета. Система ИС-ПРО загружает шаблон, отыскивает в его модулях подпрограмму ReportMain, запускает ее и ожидает завершения подпрограммы. Парамером подпрограммы ReportMain передается менеджер СОМ объектов системы. Посредством менеджера возможен доступ к СОМ объектам системы для получения информации, необходимой отчету. Объект менеджера можно использовать до окончания выполнения подпрограммы ReportMain, после ее окончания объект будет разрушен и все обращения к нему приведут к ошибке.
 - вся программа формирования отчета должна располагаться внутри подпрограммы ReportMain.

Пример программы Excel отчета

'Отчет состоит из данных двух таблиц
' ptngrpk - список групп контрагентов
' ptnrk - список контрарентов
' связь между таблицами
'  ptnrk.ptngrpk_rcd = ptngrpk.ptngrpk_rcd
' поля таблиц
'  ptngrpk
'   ptngrpk_rcd - ид записи группы
'   ptngrp_cdk  - код группы
'   ptngrp_nmk  - наименование группы
'
'  ptnrk
'   ptngrpk_rcd - ид группы
'   ptn_cd      - код контрагента
'   ptn_nm      - наименование контрагента
'
'
'Порядок построения отчета:
' сканируется список групп контрагентов
' для каждой группы выбирается список соотв. контрагентов


'Экземпляр менеджера СОМ объектов
'необходим для запроса экземпляров СОМ объектов системы
Public ComManager As Object

'Generated code.
'
'Главная точка входа в программу построения отчета
'эта процедура будет вызвана системой ИС-ПРО
'после открытия шаблона отчета
Sub ReportMain(Mgr As Object)
  On Error GoTo ErrorHandler

  'Запомнить экземпляр объекта
  'переданный системой
  Set ComManager = Mgr
  
  'запуск построения отчета
  MakeReport
  
  Exit Sub
  
ErrorHandler:
  MsgBox ("Error:" & Chr( 13 ) & Err.Description)
End Sub

Private Sub MakeReport()
  'Группы конрагентов
  Dim PtnGrpObj As Object
  'Контрагенты
  Dim PtnObj As Object
  'Лист отчета
  Dim RepSheet As Worksheet
  'Начальная строка листа отчета
  Dim row As Integer

  'В случае возникновения ошибки будет выдано сообщение с текстом ошибки
  On Error GoTo ErrorHandler
  
  'Лист книги, на котором будет построен отчет
  Set RepSheet = ActiveSheet
  
  'Запросить у менеджера экземпляры двух объектов выполнения SQL запросов
  Set PtnGrpObj = ComManager.GetObjByName("Sys", "ISysSqlQuery")
  Set PtnObj = ComManager.GetObjByName("Sys", "ISysSqlQuery")
  
  'Запрос для чтения групп
  PtnGrpObj.Text = "select ptngrpk_rcd as rcd, ptngrp_cdk as cd, ptngrp_nmk as nm from ptngrpk"
  
  'Запрос для чтения контрагентов группы
  PtnObj.Text = "select ptn_cd as cd, ptn_nm as nm from ptnrk where ptngrpk_rcd = :grp_rcd"
  
  'Открыть запрос для групп
  PtnGrpObj.OpenObj
  
  'Сканировать группы
  If PtnGrpObj.First Then
    row = 3
    Do
      'Вывод наименования группы
      RepSheet.Range("B" & CStr(row) & ":C" & CStr(row)).Merge
      RepSheet.Range("A" & CStr(row) & ":C" & CStr(row)).Font.Bold = True
      RepSheet.Range("A" & CStr(row) & ":C" & CStr(row)).BorderAround (xlContinuous)
      RepSheet.Range("A" & CStr(row)).Value = PtnGrpObj.GetFieldValue("cd")
      RepSheet.Range("B" & CStr(row)).Value = PtnGrpObj.GetFieldValue("nm")
      row = row +  1 
      
      'Установка кода группы для запроса списка контрагентов
      Call PtnObj.SetParamValue("grp_rcd", PtnGrpObj.GetFieldValue("rcd"))
      
      'Открыть запрос списка контрагентов
      PtnObj.OpenObj
      
      'Сканировать список
      If PtnObj.First Then
        Do
          'Вывод записи контрагента
          RepSheet.Range("A" & CStr(row) & ":B" & CStr(row)).Merge
          RepSheet.Range("A" & CStr(row) & ":C" & CStr(row)).BorderAround (xlContinuous)
          RepSheet.Range("A" & CStr(row)).Value = PtnObj.GetFieldValue("cd")
          RepSheet.Range("C" & CStr(row)).Value = PtnObj.GetFieldValue("nm")
          row = row +  1 
        Loop While PtnObj.Next
      End If
      
      'Закрыть объект списка контрагентов
      'по окончании чтения списка для группы
      PtnObj.CloseObj
      
    Loop While PtnGrpObj.Next
      
  End If
  
  Exit Sub
  
ErrorHandler:
  MsgBox ("Error:" & Chr( 13 ) & Err.Description)
End Sub