dim Connection_String, SQL_Statement, List_Of_Tables
dim conn, rs, i, fso, field_data, flist
Const ForReading =  1 , ForWriting =  2 , ForAppending =  8 

Connection_String = "DSN=MSSQL_DB;UID=aaa;PWD=bbb"
SQL_Statement = "select * from mydb.dbo."
List_Of_Tables = "list_of_tables.txt"


set fso = CreateObject("Scripting.FileSystemObject")
set flist = fso.OpenTextFile(List_Of_Tables, ForReading, False)
set conn = CreateObject("ADODB.Connection")
conn.Open Connection_String
do while not flist.AtEndOfStream
	Export_Table( flist.ReadLine )
loop
flist.close
conn.Close


sub Export_Table(Table_Name)
	dim Output_File_Name, fout
	WScript.Echo Table_Name
	set rs = conn.Execute(SQL_Statement + Table_Name)
	Output_File_Name = Table_Name & ".dat"
	set fout = fso.CreateTextFile(Output_File_Name, True)
	'' not needed for bcp
	'for i=0 to rs.Fields.Count-1
	'	if i>0 then fout.Write chr(9)
	'	fout.Write rs.Fields(i).Name
	'next
	'fout.WriteLine

	do while not rs.eof
		for i= 0  to rs.Fields.Count- 1 
			if i> 0  then fout.Write chr( 9 )
			field_data = trim(""&rs(i))
			fout.Write field_data
		next
		fout.WriteLine
		rs.MoveNext
	loop

	rs.Close
	fout.Close
end sub