PROCEDURE refresh_record(par_block_name VARCHAR2) IS
  charpattern          VARCHAR2(2000);
  v_block              VARCHAR2(30);
  v_item               VARCHAR2(30);
  v_old_update_allowed VARCHAR2(30);
  v_opd_locking_mode   VARCHAR2(30);
  v_column_name        VARCHAR2(30);
  v_data_type          VARCHAR2(30);
  v_format             VARCHAR2(50);
  v_key_string         VARCHAR2(1000);
  v_source             VARCHAR2(1000);
  v_cursor             INTEGER;
  v_result             INTEGER;
  j                    NUMBER;
  v_sql                VARCHAR2(1000);
BEGIN
  v_block              := par_block_name;
  v_old_update_allowed := get_block_property(v_block, update_allowed);
  v_opd_locking_mode   := get_block_property(v_block, locking_mode);
  v_source := get_block_property(v_block, query_data_source_name);
  v_item   := get_block_property(v_block, first_item);
  set_block_property(v_block, update_allowed, property_true);
  set_block_property(v_block, locking_mode, delayed);
  LOOP
    IF get_item_property(v_block || '.' || v_item, primary_key) = 'TRUE'
    THEN
      v_key_string := ' where ' || get_item_property(v_block || '.' || v_item, column_name) || '=' ||
                      to_char(name_in(v_block || '.' || v_item));
      EXIT;
    END IF;
    IF v_item = get_block_property(v_block, last_item)
    THEN
      return;-- ÓÏÑ, íè÷åãî íå ïîëó÷èëîñü, êëþ÷à íåòó.
    END IF;
    v_item := get_item_property(v_block || '.' || v_item, nextitem);
  END LOOP;
  v_item := get_block_property(v_block, first_item);
  LOOP
    IF get_item_property(v_block || '.' || v_item, item_type) IN ('CHECKBOX', 'LIST', 'TEXT ITEM')
    THEN
      v_column_name := get_item_property(v_block || '.' || v_item, column_name);
      v_data_type   := get_item_property(v_block || '.' || v_item, datatype);
      IF get_item_property(v_block || '.' || v_item, item_type) IN ('TEXT ITEM')
      THEN
        v_format := get_item_property(v_block || '.' || v_item, format_mask);
      ELSE
        v_format := NULL;
      END IF;
      IF v_column_name IS NOT NULL
      THEN
        IF v_data_type IN ('DATE', 'DATETIME')
        THEN
          IF v_format IS NOT NULL
          THEN
            v_sql := 'select to_char(' || v_column_name || ',''' || v_format || ''') as res from ' ||
                     v_source || v_key_string;
          ELSE
            v_sql := 'select to_char(' || v_column_name || ') as res from ' || v_source ||
                     v_key_string;
          END IF;
        
        ELSIF v_data_type IN ('NUMBER')
        THEN
          IF v_format IS NOT NULL
          THEN
            v_sql := 'select to_char(' || v_column_name || ',''' || v_format || ''') as res from ' ||
                     v_source || v_key_string;
          ELSE
            v_sql := 'select to_char(' || v_column_name || ')  as res from ' || v_source ||
                     v_key_string;
          END IF;
        ELSIF v_data_type IN ('CHAR')
        THEN
          v_sql := 'select ' || v_column_name || ' as res from ' || v_source || v_key_string;
        END IF;
        j        := 1;
        v_cursor := dbms_sql.open_cursor;
        dbms_sql.parse(v_cursor, v_sql, 1);
        dbms_sql.define_column(v_cursor, j, charpattern, 1000);
        v_result := dbms_sql.execute(v_cursor);
      
        IF dbms_sql.fetch_rows(v_cursor) > 0
        THEN
          dbms_sql.column_value(v_cursor, 1, charpattern);
          copy(charpattern, v_block || '.' || v_item);
          dbms_sql.close_cursor(v_cursor);
        END IF;
      END IF;
    END IF;
    IF v_item = get_block_property(v_block, last_item)
    THEN
      EXIT;
    END IF;
    v_item := get_item_property(v_block || '.' || v_item, nextitem);
  END LOOP;
  execute_trigger('POST-QUERY');   
  set_record_property(get_block_property(v_block, current_record), v_block, status, new_status);
  set_record_property(get_block_property(v_block, current_record), v_block, status, query_status);
  IF v_old_update_allowed = 'FALSE'
  THEN
    set_block_property(v_block, update_allowed, property_false);
  END IF;
  set_block_property(v_block, locking_mode, IMMEDIATE);
END;