1 . MESSAGE build-ins. Bug N  3484481 

Строку состояния можно "стереть" из программы принудительно,
передав ф-ции Message длинную строку из символов CHR( 160 ).

CHR( 160 ) -  В кодировке Windows  1251  - non break space, в
кодировке UTF- 8  - это некорректный символ, но Message
build-in обрабатывает его как Non break space. Строка из
 2000  штук CHR( 160 ) затирает Status line во всех режимах:
CL8MSWIN1251 и UTF8 - без всяких последствий

Т.е. вместо Message build-ins можно воспользоваться ф-цией
UTF.ShowMes. См. текст пакета в конце письма.

 2 . SET_MENU_ITEM_PROPERTY

Menu можно "перевысветить" принудительно. Workaround'ы различны
для Main menu (в верху экрана) и для Popup menu в формах.

Для Popup menu: вроде просто достаточно последовательность команд:

SET_MENU_ITEM_PROPERTY(
  menuitem_name,
  LABEL,
  GET_MENU_ITEM_PROPERTY( menuitem_name, LABEL )
  );

Что бы пункт заново высвечивался корректно.

Для Main menu:

Меню "перевысвечивается" когда происходит навигация мужду форм.
Для того, что бы обойти проблему нужно:

I. Создать форму REDRAW_MENU как описано ниже

1. Создать пустую форму REDRAW_MENU.FMB
2. Переменовать окно WINDOW1 в REDRAW_MENU_WINDOW. Форма должна
содержать одно окно REDRAW_MENU_WINDOW.
3. Создать блок с navigatable item'ом (например
Text item BLOCK1.ITEM1)
 4 . Добавить в Forms'у триггер PRE-FORM со следующим содержанием:

DECLARE
  s varchar2(4000);
  t timer;
  f FormModule;
BEGIN
  s := :GLOBAL.CALLER;
  f := FIND_FORM( s );
  IF ID_NULL( f ) THEN
    EXIT_FORM;
  END IF;
  HIDE_WINDOW( 'REDRAW_MENU_WINDOW' );
  RAISE FORM_TRIGGER_FAILURE;
END;

II. Создать библиотеку с пакетом UTF (текст см. в конце письма),
добавить ее ко всем формам и использовать UTF.SetMenuItemPropery
вместо SET_MENU_ITEM_PROPERTY:

III. Во все Forms'ы проекта добавить триггер
WHEN-TIMER-EXPIRED со следующим содержанием:

DECLARE
  s varchar2( 100 );
BEGIN
  s := GET_APPLICATION_PROPERTY( TIMER_NAME );
  UTF.ProcessTimer( s );
END;

 3 . Ошибка с SELECT_ALL build-ins. Bug  3710017 

Workaround:
Создать C-функцию со следующим содержанием и
вызывать ее из Forms вместо SELECT_ALL

#define FUNC_SPEC __declspec(dllexport)

extern "C" FUNC_SPEC void _cdecl SelectAll( HWND hWnd )
{
  WPARAM wParam;
  LPARAM lParam;

  if ( ! hWnd  )
  {
    hWnd = ::GetFocus();
  }

  ::SendMessage( hWnd, EM_SETSEL,  0 , - 1  );
}

Содержание пакета UTF

 --- PACKAGE SPECIFICATION 

PACKAGE utf IS

codepage varchar2( 20 );
 -- Non break space char. 
nbsp varchar2( 10 );

PROCEDURE ProcessTimer( timer_name varchar2);

PROCEDURE ShowMes( s varchar2, n number := ACKNOWLEDGE );

PROCEDURE SetMenuItemProperty(
        menuitem_name  varchar2,
        property NUMBER,
        val NUMBER
);

PROCEDURE SetMenuItemProperty(
        menuitem_name VARCHAR2,
        property NUMBER,
        val VARCHAR2
);
 /*
PROCEDURE SelectAll( itm varchar2 := '' );
*/ 
END;

 --- PACKAGE BODY 

PACKAGE BODY UTF IS

futil_libhandle ora_ffi.libHandleType;
SelectAll_fhandle ora_ffi.funcHandleType;

 /*
** Данный пакет содержит Workaround
** для ряда встроенных Build-Ins которые
** некоректно работают в режиме Utf8
** или с "новым" Forms (path 16)
*/ 

 -- This function does the same as MESSAGE build-in 
 -- (bug N 3484481) 
PROCEDURE ShowMes( s varchar2, n number ) IS
  tmp varchar2( 4000 );
BEGIN
  IF codepage='UTF8' THEN
     -- This seems to be incorect, because Non Break Space 
     -- has the other code in Unicode. But this works. 
    tmp := LPAD( chr( 160 ),  2000 , chr( 160 ) );
    Message( tmp, NO_ACKNOWLEDGE );
    SYNCHRONIZE;
  END IF;
  Message( s, n );
END ShowMes;

 -- The following functions are for internal use only. 
PROCEDURE CreaTimer( timer_name varchar2 ) IS
  t timer;
BEGIN
  t := FIND_TIMER( timer_name );
  IF ID_NULL( t ) THEN
    t := CREATE_TIMER( timer_name,  1 , NO_REPEAT );
  END IF;
END CreaTimer;

PROCEDURE ProcessTimer( timer_name varchar2) IS
  s varchar2( 2000 );
  f FormModule;
BEGIN
  IF codepage='UTF8' THEN
    IF timer_name = 'REDRAW_MENU' THEN
      COPY( NAME_IN( 'SYSTEM.CURRENT_FORM' ), 'GLOBAL.CALLER' );
      f := FIND_FORM( 'REDRAW_MENU' );
      IF ID_NULL( f ) THEN
        OPEN_FORM( 'REDRAW_MENU' );
      ELSE
        GO_FORM( f );
      END IF;
    END IF;
  END IF;
END ProcessTimer;

 -- This function does the same as SET_MENU_ITEM_PROPERTY build-in  
PROCEDURE SetMenuItemProperty( 
  menuitem_name  VARCHAR2,
  property NUMBER,
  val NUMBER
) IS
  tmp varchar2( 4000 );
BEGIN
  SET_MENU_ITEM_PROPERTY( menuitem_name, property, val );               
  IF codepage='UTF8' THEN
    CreaTimer( 'REDRAW_MENU' );
    SET_MENU_ITEM_PROPERTY(
      menuitem_name,
      LABEL,
      GET_MENU_ITEM_PROPERTY( menuitem_name, LABEL )
     );
  END IF;
END SetMenuItemProperty;

 -- This function does the same as SET_MENU_ITEM_PROPERTY build-in  
PROCEDURE SetMenuItemProperty( 
  menuitem_name  VARCHAR2,
  property NUMBER,
  val VARCHAR2
) IS
BEGIN
  SET_MENU_ITEM_PROPERTY( menuitem_name, property, val );               
  IF codepage='UTF8' THEN
    CreaTimer( 'REDRAW_MENU' );
    SET_MENU_ITEM_PROPERTY(
      menuitem_name,
      LABEL,
      GET_MENU_ITEM_PROPERTY( menuitem_name, LABEL )
     );
  END IF;
END SetMenuItemProperty;

PROCEDURE ff_SelectAll(
  fhandle Ora_FFi.funchandletype,
  hWnd pls_integer
);
PRAGMA interface( C, ff_SelectAll,  11265  );

 -- This function doesn the same as SELECT_ALL 
 -- build-in. SELECT_ALL doesn't work with
-- the patch 16. (bug N 3710017)
PROCEDURE SelectAll( itm varchar2 ) IS
BEGIN
  IF itm is not NULL then
    GO_ITEM( itm );
    SYNCHRONIZE;
  END IF;
  ff_SelectAll( SelectAll_fhandle, 0 );
END SelectAll;

PROCEDURE Init IS
  s varchar2(100);
  pos number;
BEGIN
  TOOL_ENV.GetVar( 'NLS_LANG', s );
  pos := instr( s, '.' );
  codepage := substr( s, pos +1 );
  IF codepage='UTF8' THEN 
    nbsp := chr(  49824  );
  ELSE
    nbsp := chr(  160  );
  END IF;
 /*
  -- Register SelectAll function from FUTILS.DLL
  IF Ora_Ffi.Is_Null_Ptr( futil_libhandle ) THEN
    futil_libhandle:=ora_ffi.load_library(NULL,'futils.dll');
    -- SelectAll
    SelectAll_fhandle := Ora_Ffi.Register_Function
      ( futil_libhandle, 'SelectAll', Ora_Ffi.C_Std );
    Ora_Ffi.Register_Parameter
      (SelectAll_fhandle, Ora_Ffi.C_INT );
  END IF;
*/ 
END Init;

BEGIN
  Init;
END;