create or replace procedure tmp_write_to_file(p_file_name in varchar2
                                              ,p_directory in varchar2
                                              ,p_content in blob) is
  l_file utl_file.file_type;
  l_buffer raw(32000);
  l_amount binary_integer := 32000;
  l_pos integer := 1;
  l_blob blob;
  l_blob_left number;
  l_blob_length number;
begin
  l_blob_length := dbms_lob.getlength(p_content);
  l_blob_left := l_blob_length;
  -- open the destination file.
  l_file := utl_file.fopen(p_directory
                          ,p_file_name
                          ,'WB'
                          ,32760);
  -- read chunks of the blob and write them to the file
  -- until complete.
  -- if small enough for a single write
  if l_blob_length < 32760 then
    utl_file.put_raw(l_file
                    ,p_content);
    utl_file.fflush(l_file);
  else
    -- write in pieces
    l_pos := 1;
    while l_pos < l_blob_length loop
      dbms_lob.read(p_content
                   ,l_amount
                   ,l_pos
                   ,l_buffer);
      utl_file.put_raw(l_file
                      ,l_buffer);
      utl_file.fflush(l_file);
      -- set the start position for the next cut
      l_pos := l_pos + l_amount;
      -- set the end position if less than 32000 bytes
      l_blob_left := l_blob_left - l_amount;
      if l_blob_left < 32000 then
        l_amount := l_blob_left;
      end if;
    end loop;
  end if;
  utl_file.fclose(l_file);
exception
  when others then
    -- close the file if something goes wrong.
    if utl_file.is_open(l_file) then
      utl_file.fclose(l_file);
    end if;
    raise;
end;
/

CREATE DIRECTORY TMP_DIR AS 'C:\install'
/

declare
  i number;
  v_out_buf htp.htbuf_arr;
  v_out_row_count number := 99999999;
  v_document_blob blob;
  params owa.vc_arr;
begin
  htp.init;
  owa.init_cgi_env(params);
  apex_040000.apex_application.g_public_user := 'ANONYMOUS';
  apex_040000.apex_util.set_security_group_id(10);
  apex_040000.wwv_flow_gen_api2.export( 4950 );
  owa.get_page(v_out_buf, v_out_row_count);
 
  dbms_lob.createtemporary(v_document_blob, true, dbms_lob.session);
  for i in 1..v_out_row_count loop    
    dbms_lob.writeappend(v_document_blob, utl_raw.length(utl_raw.cast_to_raw(
    
      replace(replace(v_out_buf(i),'wwv_flow_login.user_is_dba','wwv_flow_security.user_is_dba')
                                  ,upper('wwv_flow_login.user_is_dba'),upper('wwv_flow_security.user_is_dba'))
      
    )), utl_raw.cast_to_raw(
    
      replace(replace(v_out_buf(i),'wwv_flow_login.user_is_dba','wwv_flow_security.user_is_dba')
                                  ,upper('wwv_flow_login.user_is_dba'),upper('wwv_flow_security.user_is_dba'))
      
    ));
  end loop;
  
  tmp_write_to_file('XE_ADMIN.SQL', 'TMP_DIR', v_document_blob);
end;
/

drop procedure tmp_write_to_file
/

drop directory TMP_DIR
/

begin
  apex_application.g_public_user := 'ANONYMOUS';
  apex_util.set_security_group_id(10);
  
  apex_application_install.set_application_id( 4950);
  apex_application_install.set_workspace_id( 10 );
end;
/

begin
  for rec in (select *
              from dba_tab_privs t
              where t.grantee in ('APEX_040000')
              and (t.table_name, t.grantable) not in
                    (select t2.table_name, t2.grantable
                     from dba_tab_privs t2
                     where t2.grantee in 'APEX_040200')
              order by t.table_name) loop
  
    execute immediate 'grant ' || rec.privilege || ' on ' || rec.owner || '.' 
                    || rec.table_name || ' to APEX_040200' 
                    || case when rec.grantable = 'YES' then ' with grant option' end;
  end loop;
end;
/

@XE_ADMIN.SQL

alter session set current_schema = APEX_040200;

var F4000_P20_FLOW_ID varchar2(4000);
var flow_security_group_id varchar2(4000);

begin
  :F4000_P20_FLOW_ID := 4950;
  :flow_security_group_id := 10;
end;
/

begin
wwv_flow.g_import_in_progress := true;

for c1 in (select translation_flow_id
           from WWV_FLOW_LANGUAGE_MAP 
           where security_group_id = :flow_security_group_id and
           primary_language_flow_id = :F4000_P20_FLOW_ID) loop

    -- removing from reserved list
    delete from wwv_flows_reserved
    where id = c1.translation_flow_id;

   for c2 in (select id from wwv_flows
              where id = c1.translation_flow_id) loop
       delete from wwv_flows 
       where id = c2.id and security_group_id = :flow_security_group_id;
   end loop;
end loop;

delete from WWV_FLOW_LANGUAGE_MAP where primary_language_flow_id = :F4000_P20_FLOW_ID;

delete from wwv_flows 
where id = :F4000_P20_FLOW_ID and security_group_id = :flow_security_group_id;

-- removing from reserved list
delete from wwv_flows_reserved
 where id = :F4000_P20_FLOW_ID;

--
-- Delete the saved interactive reports
--
delete from wwv_flow_worksheet_rpts
 where flow_id = :F4000_P20_FLOW_ID
   and security_group_id = :flow_security_group_id;
end;
/

commit;

alter session set CURRENT_SCHEMA = SYS;