Да в xls формат не обязательно конвертировать, достаточно обычный CSV.
Он не может поддерживать или не поддерживать несколько таблиц, т.к. это обычный текст разделенный определенным символом по которому уже программа его обрабатывающаю может парсить его в таблицы. Так что это задача экселя поддерживать, с чем она и прекрасно справляется.

select * from apex_application_page_rpt 
select * from apex_application_page_rpt_cols

declare
    vURL       VARCHAR2(255);
    vBlob           BLOB;
    vCookieNameList  Owa_Cookie.vc_arr;
    vCookieValueList Owa_Cookie.vc_arr;
    vCookieCount     INTEGER;
    vCookieList      Utl_Http.cookie_table;
    vRequest         Utl_Http.req;
    vResponse        Utl_Http.resp;
    vData            RAW(32767);
BEGIN
    htp.init;
    vURL := apex_util.host_url('SCRIPT') || 'f?p=122:6:' || :session || '::::';
    DBMS_LOB.createtemporary(vBlob, FALSE);


    Owa_Cookie.get_all
      ( names    => vCookieNameList
      , vals     => vCookieValueList
      , num_vals => vCookieCount
      );
    FOR ii IN 1 .. vCookieNameList.COUNT
    LOOP
        vCookieList(ii).name   := vCookieNameList(ii);
        vCookieList(ii).value  := vCookieValueList(ii);
        vCookieList(ii).domain := ltrim( apex_util.host_url, 'http://' );
        vCookieList(ii).path   := '/';
    END LOOP;
    Utl_Http.add_cookies(vCookieList);



    vRequest := Utl_Http.begin_request(vURL);
    Utl_Http.set_header(vRequest, 'User-Agent', UPPER(OWA_UTIL.GET_CGI_ENV('HTTP_USER_AGENT')) );
    vResponse := Utl_Http.get_response(vRequest);


    LOOP
        BEGIN
            --------------------------------------------------------------------
            -- read the next junk of binary data
            --------------------------------------------------------------------
            Utl_Http.read_raw(vResponse, vData);
            --------------------------------------------------------------------
            -- append it to our blob for the pdf file
            --------------------------------------------------------------------
            Dbms_Lob.writeAppend
              ( lob_loc => vBlob
              , amount  => Utl_Raw.length(vData)
              , buffer  => vData
              );
        EXCEPTION WHEN Utl_Http.END_OF_BODY THEN
            EXIT; -- exit loop
        END;
    END LOOP;
    Utl_Http.end_response(vResponse);

    OWA_UTIL.mime_header ( 'text/html', FALSE);
    HTP.p ('Content-length: ' || dbms_lob.getlength(vBlob));
    OWA_UTIL.http_header_close;
    WPG_DOCLOAD.download_file (vBlob);
    apex_application.stop_apex_engine;
end;

vCookieList(ii).domain := ltrim( apex_util.host_url, 'http://' );

CREATE OR REPLACE PROCEDURE get_page IS

 vURL VARCHAR2(255);
 vBlob BLOB;
 vClob CLOB;
 vCookieNameList owa_cookie.vc_arr;
 vCookieValueList owa_cookie.vc_arr;
 vCookieCount INTEGER;
 vCookieList utl_http.cookie_table;
 vRequest utl_http.req;
 vResponse utl_http.resp;
 vPiece VARCHAR2(32767);
 n1 NUMBER := 1;
 n2 NUMBER := 1;
 convert_warn INTEGER;
 lang_context INTEGER := dbms_lob.default_lang_ctx;
 csid INTEGER := dbms_lob.default_csid;

BEGIN
 htp.init;
 vURL := apex_util.host_url('SCRIPT')||'f?p='||v('APP_ID')||':'||v('APP_PAGE_ID')||':' ||v('APP_SESSION')|| '::NO::::YES'; -- обращение к странице с которой эта процедура и вызвана с установкой Print_Friendly Template'а
 owa_cookie.get_all
   ( names    => vCookieNameList
   , vals     => vCookieValueList
   , num_vals => vCookieCount
   );
 FOR i IN 1 .. vCookieNameList.COUNT LOOP
  vCookieList(i).name   := vCookieNameList(i);
  vCookieList(i).value  := vCookieValueList(i);
  vCookieList(i).domain := REGEXP_REPLACE(LTRIM(apex_util.host_url, 'http://'), '\:\d{1,5}'); -- вырезка порта и "http://" из хоста
  vCookieList(i).path   := '/';
 END LOOP;
 utl_http.add_cookies(vCookieList);

 vRequest := utl_http.begin_request(vURL);
 utl_http.set_header(vRequest, 'User-Agent', UPPER(owa_util.get_cgi_env('HTTP_USER_AGENT')) );
 vResponse := utl_http.get_response(vRequest);

 dbms_lob.createtemporary(vClob, FALSE);
 LOOP
  BEGIN
   utl_http.read_text(vResponse, vPiece);
   dbms_lob.writeAppend
     ( lob_loc => vClob
     , amount  => LENGTH(vPiece)
     , buffer  => vPiece
     );
  EXCEPTION WHEN utl_http.END_OF_BODY THEN EXIT;
  END;
 END LOOP;
 utl_http.end_response(vResponse);

 FOR c IN (SELECT * FROM wwv_page_pattern ORDER BY wpp_id) LOOP
  vClob := REGEXP_REPLACE(vClob, c.wpp_from, c.wpp_to, modifier => 'n'); -- вырезка html мусора из буфера с содержимым страныцы (wwv_page_pattern - моя табличка в которой я и храню что надо вырезать)
 END LOOP;
 vClob := '<html><head><meta http-equiv="Content-Type" content="text/html; charset=UTF-8"/></head><body>'||vClob||'</body></html>';

 dbms_lob.createtemporary(vBlob, FALSE);
 dbms_lob.CONVERTTOBLOB(vBlob, vClob, dbms_lob.lobmaxsize, n1, n2, csid, lang_context, convert_warn);

 owa_util.mime_header('text/html; charset=UTF-8', FALSE);
  htp.p('Content-Disposition: attachment; filename="report.htm"');
  htp.p ('Content-length: '||dbms_lob.getlength(vBlob));
 owa_util.http_header_close;
 wpg_docload.download_file(vBlob);
 apex_application.stop_apex_engine;
END;
/