procedure markup_archive_document(
  p_masterthingid in number,
  p_thingid in number,
  p_siteid in number,
  p_language in varchar2 default portal.wwsbr_global.browserlanguage,
  p_text_query in varchar2
 ) IS
  l_clob clob;
  l_amt number :=  4000 ;
  l_pos number :=  1 ;
  l_size number;
  l_buf varchar2( 32000 );
  -- переменные для представления первичного ключа
  -- для таблицы wwdoc_document$
  l_subscriber constant wwv_docinfo.subscriber_id%type :=  1 ;
  l_name wwv_docinfo.name%type;
  l_textkey varchar2( 1024 );
 BEGIN
  -- получим ключ для таблицы wwdoc_document$
  l_name := get_filename(
   p_masterthingid => p_masterthingid,
   p_thingid => p_thingid,
   p_siteid => p_siteid,
   p_language => p_language);
  -- проверим, имеет ли текущий пользователь права
  -- на просмотр этого документа
  if not check_rights(
   p_masterthingid => p_masterthingid,
   p_thingid => p_thingid,
   p_siteid => p_siteid,
   p_language => p_language
            ) then
   raise SECURITY_EXCEPTION;
  end if;
   -- преобразуем ключ в строковое представление
  l_textkey := ctx_doc.pkencode(l_subscriber, l_name);
  
   ctx_doc.markup(index_name => 'WWSBR_DOC_CTX_INDX',
                 textkey => l_textkey,
                 restab => l_clob,
                 text_query => p_text_query,
                 tagset => 'HTML_NAVIGATE');
 
  l_size := dbms_lob.getlength(l_clob);
  l_pos :=  1 ;
  while l_size >  0  loop
   dbms_lob.read(l_clob, l_amt, l_pos, l_buf);
   l_pos := l_pos + l_amt;
   l_size := l_size - l_amt;
   htp.prn(l_buf);
  end loop;
  dbms_lob.freetemporary(l_clob);
  -- был просмотр документа - отметим это
  wpdoc.wwv_docaccessdb.adddocaccesshit (p_masterthingid => p_masterthingid,
                                   p_thingid => p_thingid,
                                   p_accesseduser => portal.wwctx_api.get_user,
                                   p_workstation => OWA_UTIL.get_cgi_env('REMOTE_ADDR'));  
  EXCEPTION
   WHEN SECURITY_EXCEPTION THEN
    htp.p('Forbidden!');
   WHEN OTHERS THEN
    htp.p(SQLERRM);
    htp.p(dbms_utility.format_error_backtrace);
 END;