PROCEDURE GET_ERROR (f_app_user   IN VARCHAR2,
                     f_mes        IN VARCHAR2,
                     f_code       IN VARCHAR2,
                     f_proc       IN VARCHAR2,
                     f_other      IN VARCHAR2 DEFAULT NULL )
IS
   /*вывод ошибок в браузер
   разработчик (есть роль DEV) видит полное сообщение, пользователь краткое
   
   v ('ADMIN_EMAIL'), v ('FROM_EMAIL') -     Substitution String в приложении
   
   F101 - неизменный альяс приложения
   */
   CURSOR c1
   IS
      SELECT   1
        FROM   dba_role_privs
       WHERE   GRANTEE = f_app_user AND GRANTED_ROLE = 'DEV';

   r1   c1%ROWTYPE;
BEGIN
   INSERT INTO TR000001 (username,
                         app_id,
                         app_page_id,
                         d_sob,
                         error,
                         process,
                         ip)
     VALUES   (f_app_user,
               nv ('APP_ID'),
               nv ('APP_PAGE_ID'),
               SYSDATE,
               f_mes,
               f_proc,
               OWA_UTIL.get_cgi_env ('REMOTE_ADDR'));

   FOR cw IN (SELECT   workspace_id
                FROM   apex_applications
               WHERE   alias = 'F101')
   LOOP
      apex_util.set_security_group_id (cw.workspace_id);
   END LOOP;

   APEX_MAIL.send (
      p_to          => v ('ADMIN_EMAIL'),
      p_from        => v ('FROM_EMAIL'),
      p_body        =>   'User='
                      || f_app_user
                      || ' app_id='
                      || nv ('APP_ID')
                      || ' page='
                      || nv ('APP_PAGE_ID')
                      || ' date='
                      || TO_CHAR (SYSDATE, 'dd.mm.yyyy hh24:mi')
                      || ' SQLERRM='
                      || f_mes
                      || ' '
                      || f_other
                      || ' proc='
                      || f_proc
                      || ' ip='
                      || OWA_UTIL.get_cgi_env ('REMOTE_ADDR'),
      p_body_html   =>   '<p>User=<b>'
                      || f_app_user
                      || '</b><br/> app_id=<b>'
                      || nv ('APP_ID')
                      || '</b><br/> page=<b>'
                      || nv ('APP_PAGE_ID')
                      || '</b><br/> date=<b>'
                      || TO_CHAR (SYSDATE, 'dd.mm.yyyy :hh24:mi')
                      || '</b><br/> SQLERRM=<b>'
                      || f_mes
                      || ' '
                      || f_other
                      || '</b><br/> proc=<b>'
                      || f_proc
                      || '</b><br/> ip=<b>'
                      || OWA_UTIL.get_cgi_env ('REMOTE_ADDR')
                      || '</b></p>',
      p_subj        => 'Сообщение об ошибке'
   );
   APEX_MAIL.push_queue;

   OPEN c1;

   FETCH c1 INTO   r1;

   IF c1%FOUND
   THEN
      HTP.p (f_mes);
   ELSE
      HTP.p ('Произошла ошибка. Повторите операцию.');
   END IF;

   CLOSE c1;
END;

BEGIN
-- тонны PL/SQL
htp.p('WIN');

COMMIT;

EXCEPTION
   WHEN OTHERS
   THEN
      get_error (:APP_USER, SQLERRM, SQLCODE,'AP_TEST',dbms_utility.FORMAT_ERROR_BACKTRACE);
      rollback;
END;

ajaxRequest = new htmldb_Get(null, $v('pFlowId'), 'APPLICATION_PROCESS=AP_TEST', 0);
ajaxRequest.add('P4_NVARIANT', $v('P4_NVARIANT'));
ajaxResponse = ajaxRequest.get();

//WIN - не возвратился, значит алерт с ошибкой
if (ajaxResponse.indexOf('WIN')==-1){
alert(ajaxResponse);
}