Create trigger dbo.EditDocDetails
       on dbo.Receipt
       after update
as
begin
     if exists ( 
                   select 1
                   from inserted
                   where Status = '9'         -- Статус закрытия документа
                         and Type in ( '21'
                                     , '22'
                                     )
                         and PoKey <> ''      -- номер документа закупки
               )
     begin
          -- обновление строк документа
          Update docdet
                 set OpenQty = newset.QtyReceived
          from dbo.Orders as doc
               inner join dbo.OrderDetail as docdet
                       on doc.StorerKey = docdet.StorerKey
                          and doc.OrderKey = docdet.OrderKey
               inner join ( 
                              select recdet.StorerKey
                                   , recdet.Sku
                                   , recdoc.Pokey
                                   , Sum( recdet.QtyReceived) as QtyReceived
                              from inserted as recdoc 
                                   inner join dbo.ReceiptDetail as recdet ( nolock )
                                           on recdoc.StorerKey = recdet.StorerKey
                                              and recdoc.ReceiptKey = recdet.ReceiptKey
                              where recdoc.Status = '9'         -- Статус закрытия документа
                                    and recdoc.Type in ( '21'   -- тип документа
                                                       , '22'   -- тип документа
                                                       )
                                    and recdoc.PoKey <> ''      -- номер документа закупки
                              group by recdet.StorerKey
                                     , recdet.Sku
                                     , recdoc.Pokey
                           ) as newset
                             on doc.PoKey = newset.PoKey
                                and docdet.StorerKey = newset.StorerKey
                                and docdet.Sku = newset.Sku
          -- обновление документа
          Update doc
                 set OpenQty = newset.QtyReceived
          from dbo.Orders as doc
               inner join ( 
                              select recdet.StorerKey
                                   , recdoc.Pokey
                                   , Sum( recdet.QtyReceived) as QtyReceived
                              from inserted as recdoc 
                                   inner join dbo.ReceiptDetail as recdet ( nolock )
                                           on recdoc.StorerKey = recdet.StorerKey
                                              and recdoc.ReceiptKey = recdet.ReceiptKey
                              where recdoc.Status = '9'         -- Статус закрытия документа
                                    and recdoc.Type in ( '21'   
                                                       , '22'   
                                                       )
                                    and recdoc.PoKey <> ''      -- номер документа закупки
                              group by recdet.StorerKey
                                     , recdoc.Pokey
                           ) as newset
                             on doc.PoKey = newset.PoKey
                                and doc.StorerKey = newset.StorerKey
     end
end