use [Adventure Works DW]
declare @x xml;
with prod as
(select top (5) [ProductKey]as[@ProdKey]
      ,[EnglishProductName]
      ,[ModelName]
      ,[EnglishDescription]
      ,[ProductAlternateKey]as[Data/ProductAlternateKey]
      ,[ProductSubcategoryKey]as[Data/SubCatKey]
      ,[ProductLine]as[Data/ProdLine]
      ,[FinishedGoodsFlag]as[Info/@FinishedG]
      ,[SizeUnitMeasureCode]as[Info/@SizeUnitCode]
      ,[Color]as[Info/Col]
      ,[WeightUnitMeasureCode]as[Info/WeightUnitCode]
      ,[Size]as[Info/Size]
      ,[Class]as[Info/Class]
      ,[Style]as[Info/Style]
      ,[LargePhoto]as[Info/Pic]
      ,[StandardCost]
      ,[ListPrice]
      ,[DealerPrice]
      ,[ReorderPoint]
      ,[DaysToManufacture]
  from [dbo].[DimProduct]
order by --hashbytes('SHA2_256',cast(ProductKey as nvarchar(64)))
		newid())
select @x=(select * from prod for xml path('Product'),elements xsinil,root('AdventureWorksDW'),binary base64)
select @x as [x]
select N'<?xml version="1.0" encoding="UTF-8"?>'+cast(@x as nvarchar(max)) as [x]

select
 xl.aw.value('(./@ProdKey)[1]','int') as [ProdKey]
,xl.aw.query('./ModelName').value('.','varchar(128)') as [ModelName]
,xl.aw.value('(./Info/@SizeUnitCode)[1]','varchar(8)') as [SizeUnitCode]
,xl.aw.query('./Data/SubCatKey').value('.','smallint') as [SubCategoryKey]
,xl.aw.query('./ListPrice').value('.','money') as [ListPrice]
,xl.aw.query('./Info/Col').value('.','varchar(32)') as [Colour]
,xl.aw.query('./Info/Pic').value('.','varbinary(max)') as [Photo]
,pr.LargePhoto as [Orig.Img]
,pr.ListPrice as [Orig.ProdLstPr]
from @x.nodes('/AdventureWorksDW/Product')as xl(aw)
left join [dbo].[DimProduct] as pr on xl.aw.value('(./@ProdKey)[1]','int')=pr.ProductKey
where xl.aw.value('(./@ProdKey)[1]','int')>200