DROP TABLE IF EXISTS #data
;
CREATE TABLE #data (
  [id]    INT,
  [month] DATE,
  [check] TINYINT
)
;
INSERT INTO
  #data
VALUES
  ( 1, '20210101', 1 ),
  ( 1, '20210201', 1 ),
  ( 1, '20210301', 1 ),
  ( 1, '20210401', 0 ),
  ( 1, '20210501', 0 ),
  ( 1, '20210601', 0 ),
  ( 1, '20210701', 0 ),
  ( 1, '20210801', 0 ),
  ( 1, '20210901', 0 ),
  ( 1, '20211001', 1 ),
  ( 1, '20211101', 1 ),
  ( 1, '20211201', 1 )
;
WITH
flg AS (
  SELECT
    [id]    = [id],
    [month] = [month],
    [check] = [check],
    [gr]    = ROW_NUMBER() OVER ( PARTITION BY [id] ORDER BY [month] )
            - ROW_NUMBER() OVER ( PARTITION BY [id], [check] ORDER BY [month] )
  FROM
    #data
),
grp AS (
  SELECT
    [id]    = [id],
    [check] = [check],
    [from]  = MIN( [month] ),
    [till]  = MAX( [month] ),
    [test]  = LAG( DATEDIFF( MONTH, MIN( [month] ), MAX( [month] ) ) ) OVER ( PARTITION BY [id] ORDER BY MIN( [month] ) )
  FROM
    flg
  GROUP BY
    [id],
    [check],
    [gr]
)
SELECT
  *
FROM
  grp
WHERE
  [test] >= 5
;

DROP TABLE IF EXISTS #data
;
CREATE TABLE #data (
  [id]    INT,
  [month] DATE,
  [check] TINYINT
)
;
INSERT INTO
  #data
VALUES
  ( 1, '20210101', 1 ),
  ( 1, '20210201', 1 ),
  ( 1, '20210301', 1 ),
  ( 1, '20210401', 0 ),
  ( 1, '20210501', 0 ),
  ( 1, '20210601', 0 ),
  ( 1, '20210701', 0 ),
  ( 1, '20210801', 0 ),
  ( 1, '20210901', 0 ),
  ( 1, '20211001', 1 ),
  ( 1, '20211101', 1 ),
  ( 1, '20211201', 1 )
;
WITH
flg AS (
  -- Поиск начал непрерывных интервалов:
  SELECT
    [id]    = [id],
    [from]  = [month],
    [till]  = DATEADD( MONTH, 5, [month] ),
    [sog]   = CASE
                WHEN [month] <= MAX( DATEADD( DAY, 180, [month] ) )
                              OVER (
                                PARTITION BY
                                  [id]
                                ORDER BY
                                  [month]
                                ROWS BETWEEN
                                  UNBOUNDED PRECEDING AND 1 PRECEDING )
                  THEN 0 
                  ELSE 1 
                END
  FROM
    #data
  WHERE
        [check] = 1
),
grp AS (
-- Идентификация строк, образующих непрерывные интервалы:
  SELECT
    [id]    = [id],
    [from]  = [from],
    [till]  = [till],
    [sog]   = [sog],
    [gr]    = SUM( [sog] ) OVER( PARTITION BY [id] ORDER BY [from], [till] )
  FROM
    flg
)
SELECT
  [id]    = [id],
  [from]  = MIN( [from] ),
  [till]  = DATEADD( MONTH, -5, MAX( [till] ) )
FROM
  grp
GROUP BY
  [id],
  [gr]
;