<%
On Error Resume Next

Dim tot_bytes, postData
Dim objConn

tot_bytes = Request.TotalBytes

If tot_bytes > 0 Then
    
    With Server.CreateObject("Adodb.Stream")
        .Charset = "utf-8" 'specify the request encoding
        .Type = 1 'adTypeBinary, a binary stream
        .Open
        .Write Request.BinaryRead(tot_bytes) 'Write bytes
        .Position = 0 ' set position to the start
        .Type = 2 ' adTypeText, stream type is text now
        postData = .ReadText 'read all text
        .Close
    End With
    
    Set objConn = Server.CreateObject("Adodb.Connection")
    objConn.Open "Provider=SQLNCLI11;Server=MyServ;Database=MyDB;Uid=sa;Pwd=MyPass;"
    
    If Err > 0 Then
        Response.Write Err.Description
    Else
        With Server.CreateObject("Adodb.Recordset")
            .Open "select * from DataFromWS where 1=0", objConn, 3, 3
            If Err > 0 Then
                Response.Write Err.Description
            End If
            .AddNew
            .Fields("data").Value = postData
            .Update
            .Close
        End With
    End If
    objConn.Close: Set objConn = Nothing
    '
    If Err > 0 Then
        Response.Write Err.Description
    Else
        Response.Write postData '"data stored successfully"
    End If
Else
    Response.Write "no post data"
End If

%>