use tempdb;
go

checkpoint;

begin tran Test;

select 'before create #t', request_owner_id as [Xact ID], object_id('#t') as [#t object_id], * from sys.dm_tran_locks where request_session_id = @@spid and request_mode = 'Sch-M';
create table #t (id int);
select 'after create #t', request_owner_id as [Xact ID], object_id('#t') as [#t object_id], * from sys.dm_tran_locks where request_session_id = @@spid and request_mode = 'Sch-M';

insert into #t values (1);
select 'after insert into #t', request_owner_id as [Xact ID], object_id('#t') as [#t object_id], * from sys.dm_tran_locks where request_session_id = @@spid and request_mode = 'Sch-M';

drop table #t;
select 'after drop #t', request_owner_id as [Xact ID], object_id('#t') as [#t object_id], * from sys.dm_tran_locks where request_session_id = @@spid and request_mode = 'Sch-M';

commit;

declare @lsn nvarchar(30), @tid nvarchar(30);
select top (1) @lsn = [Current LSN], @tid = [Transaction ID] from sys.fn_dblog(null, null) where SPID = @@spid and Operation = N'LOP_BEGIN_XACT' and [Transaction Name] = N'Test' order by [Current LSN] desc;

select
 a.[Transaction Name], a.[Xact Type], a.[Xact ID], a.Description, a.[Current LSN] as [Start LSN], c.lsn as [Finish LSN]
from
 sys.fn_dblog(null, null) a cross apply
 (select [Current LSN] from sys.fn_dblog(null, null) where [Transaction ID] = @tid and Operation = N'LOP_COMMIT_XACT') b(lsn) outer apply
 (select [Current LSN] from sys.fn_dblog(null, null) where [Transaction ID] = a.[Transaction ID] and Operation = N'LOP_COMMIT_XACT') c(lsn)
where
 a.[Current LSN] between @lsn and b.lsn and a.Operation = N'LOP_BEGIN_XACT' and a.SPID = @@spid
order by
 [Start LSN];