use tempdb
go

drop table if exists dbo.v_A_TasksMail
drop table if exists dbo.tMailTest
drop table if exists dbo.tMailTestValues
go

create table dbo.v_A_TasksMail (m_id int, m_addressFrom nvarchar(100), m_addressTo nvarchar(100), m_subject nvarchar(100), m_text nvarchar(100), m_nameFrom nvarchar(100), m_id_parent int) 
insert into dbo.v_A_TasksMail values
 (1, 'vova@yandex.ru', 'vasya@mail.ru', N'Поздравляем Вас с Новым Годом!', N'[param1] [param2]. Желаем Вам здоровья и счастья!', N'Всеволод Гаврилов', 22)
,(2, 'vova@yandex.ru', 'ivan@mail.ru', N'Поздравляем Вас с Новым Годом!', N'[param1] [param2]. Желаем Вам здоровья и счастья!', N'Всеволод Гаврилов', 22) 
,(3, 'vova@yandex.ru', 'petr@mail.ru', N'Поздравляем Вас с Новым Годом!', N'[param1] [param2]. Желаем Вам здоровья и счастья!', N'Всеволод Гаврилов', 22) 
,(4, 'gena@yandex.ru', 'masha@mail.ru', N'Услуги клининга в Санкт-Петербурге', N'Добрый день! [param25] только у нас!', N'Всеволод Гаврилов', 23) 
,(5, 'gena@yandex.ru', 'dasha@mail.ru', N'Услуги клининга в Санкт-Петербурге', N'Добрый день! [param25] только у нас!', N'Всеволод Гаврилов', 23) 
,(6, 'gena@yandex.ru', 'zinaida@mail.ru', N'Услуги клининга в Санкт-Петербурге', N'Добрый день! [param25] только у нас!', N'Всеволод Гаврилов', 23) 
,(7, 'olga@yandex.ru', 'stepan@mail.ru', N'Фильтры воды для дома и дачи', N'Добрый день! Заказывайте фильтры воды только у нас!', N'Всеволод Гаврилов', 24) 

create table dbo.tMailTest (mt_id int, mt_name nvarchar(100), m_id_parent int, mt_tag nvarchar(100)) 
insert into dbo.tMailTest values
 (1, N'Тест текста письма', 22, '[param1]') 
,(2, N'Тест текста письма', 22, '[param2]') 
,(2, N'Тест текста письма', 23, '[param25]') 

create table dbo.tMailTestValues (mtv_id int, mt_id int, mtv_value nvarchar(100))
insert into dbo.tMailTestValues values
 (1, 1, N'Добрый день!')
,(2, 1, N'Здравствуйте!') 
,(3, 1, N'Доброго времени суток!')
,(4, 2, N'Примите наши теплые поздравления!') 
,(5, 2, N'От весго нашего коллектива поздравляю Вас с Новым Годом!')
,(6, 3, N'Заказывайте услуги клининга')
,(7, 3, N'Профессиональные услуги клининга')

go

-- эта вьюха будет нужна чтобы получить случайное число в функции
create or alter view dbo.GetNewId as select newid() as new_id
go

-- получает список параметров из строки
create or alter function dbo.GetStringParams (
	@String nvarchar(max)
)
returns table
as 
/* test
select * from dbo.GetStringParams (N'asdf [param1] [param2]. Желаем Вам здоровья и счастья!')
*/
return
	select concat('[', t.ParamName, ']') as ParamName
	from string_split(@String, ']') 
		cross apply ( select charindex('[', value) as StartIndex ) c
		cross apply ( select stuff(value, 1, c.StartIndex, '') as ParamName ) t
	where c.StartIndex != 0
go

-- получает рандомное значение для переданного параметра
create or alter function dbo.GetRandomParamValue (
	@ParamName nvarchar(100)
)
returns table
as
/* test
select * from dbo.GetRandomParamValue ('[param1]')
*/
return
	select vv.mtv_value as RandomValue
	from dbo.tMailTest t
		cross apply (
			select top 1 *
			from dbo.tMailTestValues v cross join dbo.GetNewId
			where v.mt_id = t.mt_id
			order by new_id
		) vv
	where mt_tag = @ParamName
go

-- меняет параметры в строке на рандомные значения
create or alter function dbo.ReplaceParamsRandom (
	@String nvarchar(max)
)
returns nvarchar(max)
as
begin
/* test
select dbo.ReplaceParamsRandom ('P1=[param1] P2=[param2], P25=[param25]')
*/	
	-- инлайн не осилил...
	select @String = replace(@String, p.ParamName, rv.RandomValue)
	from dbo.GetStringParams(@String) p
		cross apply dbo.GetRandomParamValue(p.ParamName) rv

	return @String;

end
go

select m_id
     , m_addressFrom
     , m_addressTo
     , m_subject
     , dbo.ReplaceParamsRandom(m_text)
     , m_nameFrom
     , m_id_parent
from dbo.v_A_TasksMail