IF OBJECT_ID( 'tempdb..#temp' ) IS NOT NULL
  DROP TABLE #temp
;
CREATE TABLE #temp ( [id] INT, [dat] VARCHAR(10) )
;
INSERT INTO #temp
VALUES
  ( 3,  'dat3-1'  ),
  ( 3,  'dat3-2'  ),
  ( 3,  'dat3-3'  ),
  ( 3,  'dat3-4'  ),
  ( 3,  'dat3-6'  ),
  ( 2,  'dat2-1'  ),
  ( 2,  'dat2-2'  ),
  ( 2,  'dat2-3'  ),
  ( 2,  'dat2-4'  ),
  ( 34, 'dat34-1' ),
  ( 34, 'dat34-3' ),
  ( 34, 'dat34-4' ),
  ( 34, 'dat34-5' ),
  ( 34, 'dat34-6' ),
  ( 15, 'dat15-1' ),
  ( 15, 'dat15-2' ),
  ( 15, 'dat15-3' ),
  ( 15, 'dat15-4' ),
  ( 15, 'dat15-5' )
;
DECLARE @tsql NVARCHAR(MAX) = ''
DECLARE @max INT 
DECLARE @i INT 
;
WITH
t0 AS (
  SELECT
    [cnt] = COUNT(*)
  FROM
    #temp
  GROUP BY
    [id]
)
SELECT
  @max = MAX( [cnt] )
FROM
  t0
;
WITH
n AS (
  SELECT TOP ( @max ) 
    [rn] = ROW_NUMBER() OVER ( ORDER BY 1/0 )
  FROM
    [master]..[spt_values]
)
SELECT TOP ( @max ) 
  @tsql += ',[dat' + CONVERT( VARCHAR, [rn] ) + '] = MAX( CASE WHEN [rn] = ' + CONVERT( VARCHAR, [rn] ) + ' THEN [dat] END )'
FROM
  n
;
SELECT
  @tsql = 'WITH t0 AS ( SELECT [id], [dat], [rn] = ROW_NUMBER() OVER ( PARTITION BY [id] ORDER BY [dat] ) FROM #temp ) SELECT [id]' + @tsql + ' FROM t0 GROUP BY [id]'
;
PRINT @tsql
EXECUTE ( @tsql )