use [tempdb]
go

-- создаём код
if exists (select 1 from sys.tables where object_id = OBJECT_ID(N'dbo.tableA')) drop table dbo.tableA;
go
create table dbo.tableA ( f1 int null );
go
insert into dbo.tableA ( f1 ) values ( 1 );
go

if exists (select 1 from sys.objects WHERE object_id = OBJECT_ID(N'dbo.functionA') AND type in (N'FN', N'IF', N'TF', N'FS', N'FT'))
	drop function dbo.functionA
GO

create function dbo.functionA ()
returns int
as begin
	return (select top (1) f1 from dbo.tableA);
end
go

-- всё работает
select OBJECT_NAME(object_id), object_id, modify_date from sys.all_objects where object_id in (OBJECT_ID(N'dbo.tableA'), OBJECT_ID(N'dbo.functionA'))
go
select dbo.functionA ();
go

-- меняем код
alter table dbo.tableA add f2 int null;
alter table dbo.tableA drop column f1;
go


-- dependencies ничего не видит
-- ссылки на отсутствующие объекты
select object_name(t1.referencing_id) as [Объект],
       t1.referenced_class_desc as [Вид связи],
       t1.referenced_schema_name as [Схема ссылочного объекта],
       t1.referenced_entity_name as [Имя ссылочного объекта],
       t3.object_id as [ID ссылочного объекта]
  from sys.sql_expression_dependencies as t1
  left join sys.objects as t3 on SCHEMA_NAME(t3.schema_id) = t1.referenced_schema_name and
                                 t3.name = t1.referenced_entity_name
  where t3.object_id is null and
        len(t1.referenced_schema_name) > 2 and    -- исключаем всякие with и прочее
        len(t1.referenced_entity_name) > 3 and    -- исключаем всякие with и прочее
        t1.referenced_schema_name is not null and -- исключаем, если схема не указана
        t1.referenced_database_name is null and   -- исключаем ссылки на другие базы данных
        t1.referenced_class_desc <> 'TYPE' and    -- исключаем табличные типы
        object_name(t1.referencing_id) <> 'sp_upgraddiagrams' and
        object_name(t1.referencing_id) not like '%for_del%'
GO


-- функция не работает
select dbo.functionA ();
go

-- смотрим почему
select N'dependencies работает, только если объекты ссылаются на более старые объекты'
go
select OBJECT_NAME(object_id), object_id, modify_date from sys.all_objects where object_id in (OBJECT_ID(N'dbo.tableA'), OBJECT_ID(N'dbo.functionA'))
go