declare @xmlString varchar( 8000 )
declare @val_1 datetime
declare @val_2 datetime
declare @url varchar( 255 )

select @val_2 = GetDate()
select @val_1 = DateAdd(day, 1 -Day(@val_2), @val_2)

select @url = 'http://www.cbr.ru/scripts/XML_dynamic.asp?date_req1='+
	Convert(char( 10 ), @val_1,  103 )+'&date_req2='+
	Convert(char( 10 ), @val_2,  103 )+'&VAL_NM_RQ=R01235'

exec LoadXMLFromFile 
	@url, 
	@xmlString output

declare @h int

exec sp_xml_preparedocument  @h output, @xmlString

select 
	[Date], 
	Nominal, 
	Convert(money, replace(Value, ',', '.')) 'Value'
from 
	OpenXML (@h, '//Record',  0 )
with 
(
	[Date] char( 10 ) '@Date',
	Nominal int './Nominal',
	Value varchar( 10 ) './Value'
)

exec sp_xml_removedocument @h

CREATE PROCEDURE LoadXMLFromFile
(
	@tcFileName		VARCHAR( 255 ),
	@tcXMLString	VARCHAR( 8000 ) OUTPUT
) AS
BEGIN
	-- Scratch variables used in the script
	DECLARE @retVal INT
	DECLARE @oXML INT
	DECLARE @errorSource VARCHAR( 8000 )
	DECLARE @errorDescription VARCHAR( 8000 )
	DECLARE @loadRetVal INT

	-- Initialize the XML document
	EXEC @retVal = sp_OACreate 'MSXML2.DOMDocument', @oXML OUTPUT
	IF (@retVal <>  0 )
	BEGIN
		-- Trap errors if any
		EXEC sp_OAGetErrorInfo @oXML, @errorSource OUTPUT, @errorDescription OUTPUT
		RAISERROR (@errorDescription,  16 ,  1 )

		-- Release the reference to the COM object
		EXEC sp_OADestroy @oXML
		RETURN
	END

	EXEC @retVal = sp_OASetProperty @oXML, 'async',  0 
	IF @retVal <>  0 
	BEGIN
 		-- Trap errors if any
		EXEC sp_OAGetErrorInfo @oXML, @errorSource OUTPUT, @errorDescription OUTPUT
		RAISERROR (@errorDescription,  16 ,  1 )

		-- Release the reference to the COM object
		EXEC sp_OADestroy @oXML
		RETURN
	END

	-- Load the XML into the document
	EXEC @retVal = sp_OAMethod @oXML, 'load', @loadRetVal OUTPUT, @tcFileName
	IF (@retVal <>  0 )
	BEGIN
		-- Trap errors if any
		EXEC sp_OAGetErrorInfo @oXML, @errorSource OUTPUT, @errorDescription OUTPUT
		RAISERROR (@errorDescription,  16 ,  1 )

		-- Release the reference to the COM object
		EXEC sp_OADestroy @oXML
		RETURN
	END

	-- Get the loaded XML
	EXEC @retVal = sp_OAMethod @oXML, 'xml', @tcXMLString OUTPUT
	IF (@retVal <>  0 )
	BEGIN
		-- Trap errors if any
		EXEC sp_OAGetErrorInfo @oXML, @errorSource OUTPUT, @errorDescription OUTPUT
		RAISERROR (@errorDescription,  16 ,  1 )

		-- Release the reference to the COM object
		EXEC sp_OADestroy @oXML
		RETURN
	END

	-- Release the reference to the COM object
	EXEC sp_OADestroy @oXML

END