Наряду с writetext надо использовать

UPDATETEXT { table_name.dest_column_name dest_text_ptr }
{ NULL | insert_offset }
{ NULL | delete_length }
[ WITH LOG ]
[ inserted_data
| { table_name.src_column_name src_text_ptr } ]

Дописывая весь текст порциями.
Разберётесь?

create table TextTable
(
[ID] int identity(1,1) not null,
FText Text
)
go

set nocount on
declare @ptrval binary(16),
@sLeftPart varchar(100),
@sRightPart varchar(100),
@sCenterPart varchar(8000),
@AddStr varchar(8000),
@ID int,
@i int,
@Offset int

insert TextTable (FText) values ('')
set @ID = @@Identity

select @ptrval = TEXTPTR(FText)
from TextTable
where [ID] = @ID

--В этом цикле генерятся строки случайной длинны
--и вставляются в поле FText
set @Offset = 0
set @i = 1
while @Offset <= 500000
begin
set @sLeftPart = 'Начало порции N'+Ltrim(Str(@i,20))+' '
set @sRightPart = ' конец порции N'+Ltrim(Str(@i,20))+char(13)+char(10)
set @sCenterPart = REPLICATE('F', Round(RAND() * (8000-DataLength(@sLeftPart)-DataLength(@sRightPart)),0))

set @AddStr = @sLeftPart + @sCenterPart + @sRightPart

UPDATETEXT TextTable.FText @ptrval @Offset 0 @AddStr
set @Offset = @Offset + DataLength(@AddStr)
set @i = @i + 1
end

set nocount off

--Вот убедитесь что длина данных в FText > 500000
select DataLength(FText) from TextTable

drop table TextTable