SQL rabotaet v etom otnoshenii is ruk von ploho. Est' funktsija HOST_ID() no ona ispol'zuet PID operatsionnoi sistemy i vozvraschaet varchar(, a dlja PID v W95 zadeistvovano 10 - potomu rezul'tat nepredskazuem. Chasche vsego eto *.

Luchshe vsego ispol'zovat' VB.


Option Compare Database
Option Explicit

Public UserID As String
Public ComputerID As String

Public Declare Function GetComputerName Lib "Kernel32" Alias "GetComputerNameA" _
(ByVal lpBuffer As String, nSize As Long) As Long

Public Const MAX_COMPUTERNAME_LENGTH As Long = 15&

Public Declare Function WNetGetUser& Lib "Mpr" Alias "WNetGetUserA" _
(lpName As Any, ByVal lpUserName$, lpnLength&)

Public Function GetMachineName() As String
Dim lSize As Long
Dim sBuffer As String

sBuffer = Space$(MAX_COMPUTERNAME_LENGTH + 1)
lSize = Len(sBuffer)

If GetComputerName(sBuffer, lSize) Then
GetMachineName = Left$(sBuffer, lSize)
End If

End Function

Public Function GetWinUserName() As String
Dim cbusername As Long, UserName As String
Dim ret As Long

UserName = ""
UserName = Space(256)
cbusername = Len(UserName)
ret = WNetGetUser(ByVal 0&, UserName, cbusername)

If ret = 0 Then ' ret=0 - Success
GetWinUserName = Left(UserName, InStr(UserName, Chr(0)) - 1)
Else
GetWinUserName = "UnknownUser"
End If

End Function

Public Function GetUserAndComputerID()

UserID = GetWinUserName()
ComputerID = GetMachineName()

Debug.Print UserID
Debug.Print ComputerID

End Function

No copyright! Free to use!

Alexander