Я использую процедурку:

CREATE proc dbo.generate_add_login
@login sysname = NULL
as
set nocount on
declare @add_login varchar(2000)
if @login is not null and not exists (select name from master..syslogins where name = @login)
begin
raiserror (15007,0,1,@login) -- no login found
set nocount off
return 1
end
if @login is null
begin
declare cur_logins cursor static
for select name from master..syslogins where password is not null and sid <> 0x01
open cur_logins

fetch next from cur_logins into @login
while @@fetch_status = 0
begin
select @add_login = 'exec sp_addlogin @loginame='''+ @login + ''', @sid=' + dbo.fn_hexadecimal(sid) + ', @passwd=' + dbo.fn_hexadecimal(convert(varbinary(256),password)) + ', @encryptopt=''skip_encryption''' from master..syslogins where name = @login
print @add_login
fetch next from cur_logins into @login
end
close cur_logins
deallocate cur_logins
end
else
begin
select @add_login = 'exec sp_addlogin @loginame='''+ @login + ''', @sid=' + dbo.fn_hexadecimal(sid) + ', @passwd=' + dbo.fn_hexadecimal(convert(varbinary(256),password)) + ', @encryptopt=''skip_encryption''' from master..syslogins where name = @login
print @add_login
end

set nocount off
return 0

GO



При запуске на сервере-источнике она генерит sp_addlogin statements, которые потом надо выполнить на сервере-приемнике.
В процедурке используется функция: dbo.fn_hexadecimal(varbinary(255)) для конвертации binary в вид 0x[0-9,A-F]+
Вот ее текст:

CREATE FUNCTION dbo.fn_hexadecimal (@binvalue varbinary(255))
RETURNS varchar(255)
AS
BEGIN
declare @charvalue varchar(255)
declare @i int
declare @length int
declare @hexstring char(16)

set @charvalue = '0x'
set @i = 1
set @length = datalength(@binvalue)
set @hexstring = '0123456789ABCDEF'

while (@i <= @length)
begin

declare @tempint int
declare @firstint int
declare @secondint int

set @tempint = convert(int, substring(@binvalue,@i,1))
set @firstint = floor(@tempint/16)
set @secondint = @tempint - (@firstint*16)

set @charvalue = @charvalue +
substring(@hexstring, @firstint+1, 1) +
substring(@hexstring, @secondint+1, 1)
set @i = @i + 1
end
RETURN @charvalue
END

Не составляет проблемы переписать ее как процедрку

to Dimanch:
Не вижу противопоказаний. Просто я сначала использовал голый селект, ну а потом просто завернул его в курсор. Наверное надо было, но и так тоже работает